iniciar-programa
define-nueva-instruccion gira(t) como inicio
    repetir t veces gira-izquierda;
fin;
define-prototipo-instruccion camino(x);
define-nueva-instruccion copia-atras como inicio
    si junto-a-zumbador entonces inicio
        coge-zumbador;
        copia-atras;
        deja-zumbador;
        gira(2);
        avanzA;
        gira(2);
        deja-zumbador;
        avanza;
    fin;
fin;
define-nueva-instruccion regresa-el-de-atras como inicio
    gira(2);
    avanzA;
    gira(2);
    mientras junto-a-zumbador hacer inicio
        coge-zumbador;
        avanza;
        deja-zumbador;
        gira(2);
        avanza;
        gira(2);
    fin;
fin;
define-nueva-instruccion camino(x) como inicio
    si frente-bloqueado y derecha-bloqueada y izquierda-bloqueada entonces inicio
        si no-junto-a-zumbador entonces inicio
            repetir x veces deja-zumbador;
            gira(2);
            avanza;
            gira(2);
            sal-de-instruccion
        fin;
        copia-atras;
        repetir x veces inicio
            si junto-a-zumbador entonces inicio
                coge-zumbador;
            fin
            sino inicio
                regresa-el-de-atras;
                sal-de-instruccion;
            fin;
        fin;
        mientras junto-a-zumbador hacer coge-zumbador;
        repetir x veces deja-zumbador;
        gira(2);
        avanzA;
        gira(2);
        mientras junto-a-zumbador hacer coge-zumbador;
        sal-de-instruccion;
    fin;
    si junto-a-zumbador entonces inicio
        copia-atras;
        mientras junto-a-zumbador hacer inicio
            repetir x veces inicio
                si junto-a-zumbador entonces inicio
                    coge-zumbador;
                fin
                sino inicio
                    regresa-el-de-atras;
                    sal-de-instruccion;
                fin;
            fin;
        fin;
        gira(2);
        gira(1);
        si frente-libre entonces inicio
            avanza;
            camino(sucede(x));
        fin;
        gira(1);
        si frente-libre entonces inicio
            avanza;
            camino(sucede(x));
        fin;
        gira(1);
        si frente-libre entonces inicio
            avanza;
            camino(sucede(x));
        fin;
        gira(3);
        regresa-el-de-atras;
    fin;
fin;
    inicia-ejecucion
    repetir 4 veces inicio
        gira(1);
        si frente-libre entonces inicio
            avanza;
            camino(1);
        fin;
    fin;
        apagate;
    termina-ejecucion
finalizar-programa
