iniciar-programa
    define-nueva-instruccion norte como mientras no-orientado-al-norte hacer gira-izquierda;
    define-nueva-instruccion este como mientras no-orientado-al-este hacer gira-izquierda;
    define-nueva-instruccion oeste como mientras no-orientado-al-oeste hacer gira-izquierda;
    define-nueva-instruccion sur como mientras no-orientado-al-sur hacer gira-izquierda;
    define-nueva-instruccion corre como mientras frente-libre hacer avanza;
    define-nueva-instruccion quita(x) como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            quita(x);
            coge-zumbador;
        fin sino inicio
            repetir x veces deja-zumbador;
        fin;
    fin;
    define-nueva-instruccion divide(x) como inicio
        si junto-a-zumbador y no-orientado-al-sur entonces inicio
            repetir x veces inicio
                si junto-a-zumbador y no-orientado-al-sur entonces inicio
                    coge-zumbador;
                fin sino inicio
                    sur;
                    deja-zumbador;
                fin;
            fin;
            si no-orientado-al-sur entonces inicio
                divide(x);
                repetir x veces deja-zumbador;
            fin sino inicio
                quita(x);
            fin;
        fin sino inicio
             si no-orientado-al-sur entonces norte;
         fin;
    fin;
    define-nueva-instruccion compara(x) como inicio
        si junto-a-zumbador y no si-es-cero(x) entonces inicio
            coge-zumbador;
            compara(precede(x));
            deja-zumbador;
        fin sino inicio
            mientras junto-a-zumbador hacer coge-zumbador;
        fin;
    fin;
    define-nueva-instruccion visitado(x) como inicio
        si junto-a-zumbador y no si-es-cero(x)entonces inicio
            si junto-a-zumbador entonces inicio
                coge-zumbador;
                visitado(precede(x));
            fin;
         fin sino inicio
            si junto-a-zumbador entonces inicio
                repetir 101 veces deja-zumbador;
                sur;
            fin sino inicio
                repetir 101 veces deja-zumbador;
                repetir x veces coge-zumbador;
            fin;
        fin;
    fin;
    define-prototipo-instruccion busca(x);
    define-nueva-instruccion camina(x) como inicio
        norte;
        si frente-libre entonces inicio
            avanza;
            busca(x);
            sur;
            avanza;
        fin;
        este;
        si frente-libre entonces inicio
            avanza;
            busca(x);
            oeste;
            avanza;
        fin;
        sur;
        si frente-libre entonces inicio
            avanza;
            busca(x);
            norte;
            avanza;
        fin;
        oeste;
        si frente-libre entonces inicio
            avanza;
            busca(x);
            este;
            avanza;
        fin;
    fin;
    define-nueva-instruccion busca(x) como inicio
        si izquierda-bloqueada y derecha-bloqueada y frente-bloqueado entonces inicio
            si junto-a-zumbador entonces inicio
                compara(x);
            fin sino inicio
                repetir x veces deja-zumbador;
            fin;
        fin sino inicio
            este;
            visitado(101);
            si no-orientado-al-sur entonces inicio
                este;
                divide(x);
                si orientado-al-norte entonces inicio
                    repetir 101 veces deja-zumbador;
                    camina(sucede(x));
                    repetir 101 veces coge-zumbador;
                fin;
            fin;
        fin;
    fin;
    inicia-ejecucion
        busca(0);
        apagate;
    termina-ejecucion
finalizar-programa
