iniciar-programa
define-prototipo-instruccion busqueda(x);
define-nueva-instruccion gira(q) como repetir q veces gira-izquierda;

define-nueva-instruccion checa(x) como inicio
    si junto-a-zumbador entonces repetir x veces inicio
        si junto-a-zumbador entonces inicio
             si orientado-al-norte entonces coge-zumbador;
             si  orientado-al-sur entonces deja-zumbador;
        fin sino inicio
            deja-zumbador;
            gira(2);
        fin;
    fin;
    si junto-a-zumbador entonces inicio
        si orientado-al-norte entonces inicio
            checa(x);
            repetir x veces deja-zumbador;
        fin sino inicio
            repetir x veces inicio
                si junto-a-zumbador entonces inicio
                     si orientado-al-norte entonces deja-zumbador;
                     si  orientado-al-sur entonces coge-zumbador;
                fin sino inicio
                    deja-zumbador;
                    gira(2);
                fin;
            fin;
            gira(2);
        fin;
    fin sino inicio
        repetir x veces deja-zumbador;
    fin;
fin;

define-nueva-instruccion resta(x) como inicio
    si junto-a-zumbador entonces repetir x veces coge-zumbador;
    si junto-a-zumbador entonces inicio
        resta(x);
        repetir x veces deja-zumbador;
    fin sino inicio
        busqueda(sucede(x));
        repetir x veces deja-zumbador;
    fin;
fin;

define-nueva-instruccion compara(x) como inicio
    repetir x veces inicio
        si junto-a-zumbador entonces inicio
            si frente-bloqueado entonces coge-zumbador;
            si frente-libre entonces deja-zumbador;
        fin sino inicio
            gira(2);
            deja-zumbador;
        fin;
    fin;
    si frente-libre entonces inicio
        repetir x veces inicio
            si junto-a-zumbador entonces inicio
                si frente-bloqueado entonces deja-zumbador;
                si frente-libre entonces coge-zumbador;
            fin sino inicio
                gira(2);
                deja-zumbador;
            fin;
        fin;
    fin sino inicio
        mientras junto-a-zumbador hacer coge-zumbador;
        repetir x veces deja-zumbador;
    fin;
fin;

define-nueva-instruccion busqueda(x) como inicio
    si junto-a-zumbador entonces inicio
        si orientado-al-norte entonces inicio
            checa(x);
            si orientado-al-sur entonces inicio
                gira(2);
            fin sino inicio
                resta(x);
            fin;
        fin;
        si orientado-al-sur entonces inicio
            gira(2);
            checa(x);
            si orientado-al-norte entonces inicio
                gira(2);
                resta(x);
            fin;
        fin;
        si orientado-al-este entonces inicio
            gira(1);
            checa(x);
            si orientado-al-sur entonces inicio
                gira(1);
            fin sino inicio
                gira(3);
                resta(x);
            fin;
        fin;
        si orientado-al-oeste entonces inicio
            gira(3);
            checa(x);
            si orientado-al-sur entonces inicio
                gira(3);
            fin sino inicio
                gira(1);
                resta(x);
            fin;
        fin;
    fin sino inicio
        repetir 4 veces inicio
            gira(1);
            si frente-libre entonces inicio
                avanzA;
                si izquierda-bloqueada y frente-bloqueado y derecha-bloqueada entonces inicio
                    si no junto-a-zumbador entonces inicio
                        repetir x veces deja-zumbador;
                    fin sino inicio
                        compara(x);
                    fin;
                fin sino inicio
                    si junto-a-zumbador entonces busqueda(x);
                fin;
                    gira(2);
                    avanza;
                    gira(2);
            fin;
        fin;
    fin;
fin;

    inicia-ejecucion
    busqueda(1);
        apagate;
    termina-ejecucion
finalizar-programa
