iniciar-programa
    define-nueva-instruccion gira (n) como inicio
        repetir n veces gira-izquierda;
    fin;
    define-nueva-instruccion norte como inicio
        mientras no-orientado-al-norte hacer gira-izquierda;
    fin;
    define-nueva-instruccion sur como inicio
        mientras no-orientado-al-sur hacer gira-izquierda;
    fin;
    define-nueva-instruccion este como inicio
        mientras no-orientado-al-este hacer gira-izquierda;
    fin;
    define-nueva-instruccion oeste como inicio
        mientras no-orientado-al-oeste hacer gira-izquierda;
    fin;
    define-nueva-instruccion deja (n) como inicio
        mientras junto-a-zumbador hacer coge-zumbador;
        repetir n veces deja-zumbador;
    fin;
    define-nueva-instruccion ubica1 como inicio
        sur;
        mientras frente-libre hacer avanza;
        oeste;
        mientras frente-libre hacer avanza;
        norte;
    fin;
    define-nueva-instruccion propagacion como inicio
        norte;
        si frente-libre entonces inicio
            avanza;
            deja (1);
            sur;
            avanza;
        fin;
        sur;
        si frente-libre entonces inicio
            avanza;
            deja (1);
            norte;
            avanza;
        fin;
        este;
        si frente-libre entonces inicio
            avanza;
            deja (1);
            oeste;
            avanza;
        fin;
        oeste;
        si frente-libre entonces inicio
            avanza;
            deja (1);
            este;
            avanza;
        fin;
    fin;
    define-nueva-instruccion siguiente_abajo como inicio
        este;
        si frente-libre entonces inicio
            avanza;
            sur;
            mientras frente-libre hacer avanza;
            norte;
        fin
        sino inicio
            sur;
            mientras frente-libre hacer avanza;
        fin;
    fin;
    define-nueva-instruccion siguiente_arriba como inicio
        oeste;
        si frente-libre entonces inicio
            avanza;
            norte;
            mientras frente-libre hacer avanza;
            sur;
        fin
        sino inicio
            norte;
            mientras frente-libre hacer avanza;
        fin;
    fin;
    define-nueva-instruccion columna como inicio
        norte;
        si frente-libre entonces inicio
            si junto-a-zumbador entonces inicio
                avanza;
                columna;
                si frente-libre entonces avanza;
                propagacion;
                sur;
            fin
            sino inicio
                avanza;
                columna;
                si frente-libre entonces avanza;
            fin;
        fin
        sino inicio
            si junto-a-zumbador entonces inicio
                siguiente_abajo;
                si orientado-al-norte entonces inicio
                    columna;
                    siguiente_arriba;
                    propagacion;
                    sur;
                fin
                sino inicio
                    norte;
                    mientras frente-libre hacer avanza;
                    sur;
                    propagacion;
                    sur;
                fin;
            fin
            sino inicio
                siguiente_abajo;
                si orientado-al-norte entonces inicio
                    columna;
                    siguiente_arriba;
                fin
                sino inicio
                    norte;
                    mientras frente-libre hacer avanza;
                    sur;
                fin;
            fin;
        fin;
    fin;
    define-nueva-instruccion arraza como inicio
        norte;
        columna;
        ubica1;
    fin;
    define-nueva-instruccion avanzar-casilla como inicio
        si frente-libre entonces inicio
            avanza;
        fin
        sino inicio
            sur;
            mientras frente-libre hacer avanza;
            este;
            si frente-libre entonces inicio
                avanza;
                norte;
            fin
            sino inicio
                sur;
            fin;
        fin;
    fin;
    define-nueva-instruccion colecta como inicio
        si orientado-al-sur entonces inicio
            ubica1;
            mientras junto-a-zumbador hacer coge-zumbador;
        fin
        sino inicio
            si junto-a-zumbador entonces inicio
                avanzar-casilla;
                colecta;
                deja-zumbador;
            fin
            sino inicio
                avanzar-casilla;
                colecta;
            fin;
        fin;
    fin;
    define-nueva-instruccion influenza (n) como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            influenza (sucede (n));
        fin
        sino inicio
            repetir n veces arraza;
            colecta;
        fin;
    fin;
    inicia-ejecucion
        influenza (0);
        apagate;
    termina-ejecucion
finalizar-programa
