iniciar-programa
    define-nueva-instruccion dispersa como inicio
        repetir 4 veces inicio
            si frente-libre entonces inicio
                avanza;
                deja-zumbador;
                repetir 2 veces gira-izquierda;
                avanza;
                gira-izquierda;
            fin
            sino inicio
                repetir 3 veces gira-izquierda;
            fin;
        fin;
    fin;
    define-nueva-instruccion origen como inicio
        mientras no-orientado-al-oeste hacer gira-izquierda;
        mientras frente-libre hacer avanza;
        gira-izquierda;
        mientras frente-libre hacer avanza;
        repetir 2 veces gira-izquierda;
        si frente-bloqueado entonces repetir 3 veces gira-izquierda;
    fin;
    define-nueva-instruccion siguiente-fila como inicio
        repetir 2 veces gira-izquierda;
        mientras frente-libre hacer avanza;
        gira-izquierda;
        si frente-libre entonces inicio
            avanza;
            gira-izquierda;
        fin;
    fin;
    define-nueva-instruccion dia como inicio
        mientras frente-libre hacer inicio
            si junto-a-zumbador entonces repetir 4 veces deja-zumbador;
            si frente-libre entonces avanza;
            si frente-bloqueado entonces inicio
                si junto-a-zumbador entonces repetir 4 veces deja-zumbador;
                siguiente-fila;
            fin;
        fin;
        origen;
        mientras frente-libre hacer inicio
            si junto-a-zumbador entonces inicio
                repetir 4 veces si junto-a-zumbador entonces coge-zumbador;
                si junto-a-zumbador entonces inicio
                    dispersa;
                fin
                sino inicio
                    deja-zumbador;
                fin;
            fin;
            si frente-libre entonces avanza;
            si frente-bloqueado entonces inicio
                si junto-a-zumbador entonces inicio
                    repetir 4 veces si junto-a-zumbador entonces coge-zumbador;
                    si junto-a-zumbador entonces inicio
                        dispersa;
                    fin
                    sino inicio
                        deja-zumbador;
                    fin;
                fin;
                siguiente-fila;
            fin;
        fin;
        origen;
    fin;
    define-nueva-instruccion formula como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            formula;
            dia;
        fin;
    fin;
    define-nueva-instruccion contando como inicio
        si frente-libre entonces inicio
            si junto-a-zumbador entonces inicio
                avanza;
                si frente-bloqueado entonces inicio
                    si junto-a-zumbador entonces inicio
                        siguiente-fila;
                        contando;
                        repetir 2 veces deja-zumbador;
                    fin
                    sino inicio
                        siguiente-fila;
                        contando;
                        deja-zumbador;
                    fin;
                fin
                sino inicio
                    contando;
                    deja-zumbador;
                fin;
            fin
            sino inicio
                si frente-libre entonces avanza;
                si frente-bloqueado entonces inicio
                    si junto-a-zumbador entonces inicio
                        siguiente-fila;
                        contando;
                        deja-zumbador;
                    fin
                    sino inicio
                        siguiente-fila;
                        contando;
                    fin;
                fin
                sino inicio
                    contando;
                fin;
            fin;
        fin
        sino inicio
            origen;
            mientras junto-a-zumbador hacer coge-zumbador;
        fin;
    fin;
    inicia-ejecucion
        si frente-bloqueado entonces repetir 3 veces gira-izquierda;
        formula;
        contando;
        apagate;
    termina-ejecucion
finalizar-programa
