iniciar-programa
   define-nueva-instruccion gira(n) como inicio
      repetir n veces
         gira-izquierda;
   fin;
   define-nueva-instruccion norte como inicio
       mientras no-orientado-al-norte hacer
          gira(1);
   fin;
   define-nueva-instruccion sur como inicio
       mientras no-orientado-al-sur hacer
          gira(1);
   fin;
   define-nueva-instruccion este como inicio
       mientras no-orientado-al-este hacer
          gira(1);
   fin;
   define-nueva-instruccion oeste como inicio
       mientras no-orientado-al-oeste hacer
          gira(1);
   fin;
   define-nueva-instruccion rellena como inicio
      si junto-a-zumbador entonces inicio
         coge-zumbador;
         si junto-a-zumbador entonces inicio
            deja-zumbador;
         fin
         sino inicio
            deja-zumbador;
            deja-zumbador;
         fin;
      fin;
     si frente-libre entonces inicio
        avanza;
        rellena;
     fin
     sino inicio
        si junto-a-zumbador entonces inicio
           coge-zumbador;
           si junto-a-zumbador entonces inicio
              deja-zumbador;
           fin
           sino inicio
              deja-zumbador;
              deja-zumbador;
           fin;
        fin;
        norte;
        si frente-libre entonces inicio
           avanza;
           oeste;
           mientras frente-libre hacer
              avanza;
           este;
           rellena;
        fin
        sino inicio
           oeste;
           mientras frente-libre hacer
              avanza;
           sur;
           mientras frente-libre hacer
              avanza;
        fin;
      fin;
   fin;
   define-nueva-instruccion busca como inicio
      si junto-a-zumbador entonces inicio
        coge-zumbador;
        si junto-a-zumbador entonces inicio
           deja-zumbador;
           norte;
           si frente-libre entonces inicio
              avanza;
              si no-junto-a-zumbador entonces
                 deja-zumbador;
              sur;
              avanza;
           fin;
           sur;
           si frente-libre entonces inicio
              avanza;
              si no-junto-a-zumbador entonces
                 deja-zumbador;
              norte;
              avanza;
           fin;
           este;
           si frente-libre entonces inicio
              avanza;
              si no-junto-a-zumbador entonces
                 deja-zumbador;
              oeste;
              avanza;
           fin;
           oeste;
           si frente-libre entonces inicio
              avanza;
              si no-junto-a-zumbador entonces
                 deja-zumbador;
              este;
              avanza;
           fin;
        fin
        sino inicio
           deja-zumbador;
        fin;
      fin;
      este;
      si frente-libre entonces inicio
            avanza;
            busca;
      fin
      sino inicio
         norte;
         si frente-libre entonces inicio
            avanza;
            oeste;
            mientras frente-libre hacer
               avanza;
            este;
            busca;
         fin
         sino inicio
            oeste;
            mientras frente-libre hacer
               avanza;
            sur;
            mientras frente-libre hacer
               avanza;
         fin;
      fin;
   fin;
   define-nueva-instruccion cuenta(n) como inicio
      si junto-a-zumbador entonces inicio
         mientras junto-a-zumbador hacer
            coge-zumbador;
         cuenta(sucede(n));
      fin
      sino inicio
         si frente-libre entonces inicio
            avanza;
            cuenta(n);
         fin
         sino inicio
             norte;
             si frente-libre entonces inicio
                avanza;        
                oeste;
                mientras frente-libre hacer
                   avanza;
                este;
                cuenta(n);
             fin
             sino inicio
                oeste;
                mientras frente-libre hacer
                   avanza;
                sur;
                mientras frente-libre hacer
                   avanza;
                repetir n veces
                   deja-zumbador;
                apagate;
             fin;
          fin;
      fin;
   fin;
   define-nueva-instruccion influenza(n) como inicio
      si junto-a-zumbador entonces inicio
          coge-zumbador;
          influenza(sucede(n));
      fin
      sino inicio
         repetir n veces inicio
            este;
            rellena;
            busca;
          fin;
          este;
          cuenta(0);
      fin;
   fin;
    inicia-ejecucion
       influenza(0);
        apagate;
    termina-ejecucion
finalizar-programa
