iniciar-programa
    define-nueva-instruccion gira(z) como inicio
        repetir z veces gira-izquierda;
    fin;
    define-nueva-instruccion c11 como inicio
        mientras no-orientado-al-sur hacer gira-izquierda;
        mientras frente-libre hacer avanza;
        gira(3);
        mientras frente-libre hacer avanza;
        gira(3);
    fin;
    define-nueva-instruccion busk como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            si no-junto-a-zumbador entonces inicio
                deja-zumbador;
                repetir 4 veces inicio
                    si frente-libre entonces inicio
                        avanza;
                        si no-junto-a-zumbador entonces repetir 2 veces deja-zumbador sino inicio
                            coge-zumbador;
                            si junto-a-zumbador entonces inicio
                                deja-zumbador;
                                repetir 2 veces deja-zumbador;
                            fin sino deja-zumbador;
                        fin;
                        gira(2);
                        si frente-libre entonces avanza;
                        gira(1);
                    fin sino gira(3);
                fin;
            fin sino deja-zumbador;
        fin;
    fin;
    define-nueva-instruccion propagar como inicio
        mientras no-orientado-al-este hacer inicio
            mientras frente-libre y no-junto-a-zumbador hacer avanza;
            si junto-a-zumbador entonces busk;
            si frente-libre entonces avanza;
            si frente-bloqueado y junto-a-zumbador entonces busk;
            si frente-bloqueado entonces inicio
                gira(2);
                mientras frente-libre hacer avanza;
                gira(1);
                si frente-libre entonces inicio
                    avanza;
                    gira(1);
                fin;
            fin;
        fin;
    fin;
    define-nueva-instruccion limpiar como inicio
        mientras no-orientado-al-este hacer inicio
            mientras no-junto-a-zumbador y frente-libre hacer avanza;
            si junto-a-zumbador entonces inicio
                coge-zumbador;
                si junto-a-zumbador entonces mientras junto-a-zumbador hacer coge-zumbador;
                si no-junto-a-zumbador entonces deja-zumbador;
            fin;
            si frente-libre entonces avanza;
            si frente-bloqueado y junto-a-zumbador entonces inicio
                coge-zumbador;
                si junto-a-zumbador entonces mientras junto-a-zumbador hacer coge-zumbador;
                si no-junto-a-zumbador entonces deja-zumbador;
            fin;
            si frente-bloqueado entonces inicio
                gira(2);
                mientras frente-libre hacer avanza;
                gira(1);
                si frente-libre entonces inicio
                    avanza;
                    gira(1);
                fin;
            fin;
        fin;
    fin;
    define-nueva-instruccion contar(n) como inicio
        mientras frente-libre y no-junto-a-zumbador hacer avanza;
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            contar(sucede(n));
        fin;
        si no-junto-a-zumbador entonces inicio
            si frente-bloqueado entonces inicio
                gira(2);
                mientras frente-libre hacer avanza;
                gira(1);
                si frente-libre entonces inicio
                    avanza;
                    gira(1);
                    contar(n);
                fin sino inicio
                    gira(2);
                    mientras frente-libre hacer avanza;
                    repetir n veces deja-zumbador;
                    apagate;
                fin;
            fin;
        fin;
    fin;
    define-nueva-instruccion dias(n) como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            dias(sucede(n));
        fin;
        si no-junto-a-zumbador entonces inicio
            repetir n veces inicio
                propagar;
                c11;
                limpiar;
                c11;
            fin;
            contar(0);
            apagate;
        fin;
    fin;
inicia-ejecucion
    dias(0);
        apagate;
    termina-ejecucion
finalizar-programa
