iniciar-programa
    define-nueva-instruccion norte como  mientras no orientado-al-norte hacer gira-izquierda;
    define-nueva-instruccion sur como mientras no orientado-al-sur hacer gira-izquierda;
    define-nueva-instruccion este como mientras no orientado-al-este hacer gira-izquierda;
    define-nueva-instruccion oeste como mientras no orientado-al-oeste hacer gira-izquierda;

    define-nueva-instruccion ubicar como inicio
        si frente-libre entonces inicio
            avanza;
        fin sino inicio
            si izquierda-libre entonces inicio
                gira-izquierda;
                avanza;
                gira-izquierda;
                mientras frente-libre hacer inicio
                    avanza;
                fin;
                gira-izquierda;
                gira-izquierda;
            fin;
        fin;
    fin;
    define-nueva-instruccion expandir como inicio
        deja-zumbador;
        norte;
        repetir 4 veces inicio
            si frente-libre entonces inicio
                avanza;
                si no junto-a-zumbador entonces inicio
                    deja-zumbador;
                    deja-zumbador;
                fin;
                gira-izquierdA;
                gira-izquierdA;
                avanza;
                gira-izquierda;
            fin sino inicio
                gira-izquierda;
                gira-izquierda;
                gira-izquierdA;
            fin;
        fin;
        este;
    fin;

    define-nueva-instruccion buscar(n) como inicio
        mientras frente-libre o izquierda-libre hacer inicio
            si junto-a-zumbador entonces inicio
                coge-zumbador;
                si no junto-a-zumbador entonces inicio
                    expandir;
                fin sino inicio
                    deja-zumbador
                fin;
            fin;
            ubicar;
        fin;
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            si no junto-a-zumbador entonces inicio
                expandir;
            fin sino inicio
                deja-zumbador;
            fin;
        fin;
    fin;

    define-nueva-instruccion recoger como inicio
        mientras frente-libre o izquierda-libre hacer inicio
            si junto-a-zumbador entonces inicio
                coge-zumbador;
                si no junto-a-zumbador entonces inicio
                    deja-zumbador;
                fin;
            fin;
            ubicar;
        fin;
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            si no junto-a-zumbador entonces inicio
                deja-zumbador;
            fin;
        fin;
    fin;

    define-nueva-instruccion dias(n) como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            dias(sucede(n));
        fin sino inicio
            repetir n veces inicio
                buscar(0);
                oeste;
                recoger;
                este;
            fin;
        fin;
    fin;

    define-nueva-instruccion juntar(n) como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            juntar(sucede(n));
        fin sino inicio
            si frente-libre entonces inicio
                avanza;
                juntar(0);
            fin sino inicio
                si frente-bloqueado y izquierda-libre entonces inicio
                    norte;
                    avanza;
                    oeste;                                                                  
                    mientras frente-libre hacer inicio
                        avanza;
                    fin;
                    este;
                    juntar(0);
                fin;
            fin;
            sur; mientras frente-libre hacer inicio avanza; fin;
            oeste; mientras frente-libre hacer inicio avanza; fin;
            este;
            si no si-es-cero(n) entonces inicio
                repetir n veces inicio
                    deja-zumbador;
                fin;
            fin;
        fin;
    fin;

    inicia-ejecucion
        este;
        dias(0);
        juntar(0);
        apagate;
    termina-ejecucion
finalizar-programa
