iniciar-programa
    define-nueva-instruccion este como mientras no orientado-al-este hacer gira-izquierda;
    define-nueva-instruccion media-vuelta como repetir 2 veces gira-izquierda;

    define-nueva-instruccion ir11 como inicio
        media-vuelta;
        mientras frente-libre hacer inicio
            avanza;
        fin;
        gira-izquierdA;
        mientras frente-libre hacer inicio
            avanza;
        fin;
        gira-izquierda;
    fin;

    define-nueva-instruccion expandir como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            si no junto-a-zumbador entonces inicio
                deja-zumbador;
                repetir 4 veces inicio
                    gira-izquierda;
                    si frente-libre entonces inicio
                        avanza;
                        si no junto-a-zumbador entonces inicio
                            deja-zumbador;
                            si orientado-al-este o orientado-al-norte entonces
                                deja-zumbador;
                        fin;
                        media-vuelta;
                        avanza;
                    fin sino media-vuelta;
                fin;
            fin;
        fin;
    fin;

    define-nueva-instruccion avanzar como inicio
        si frente-libre entonces inicio
            avanza;
        fin sino inicio
            gira-izquierda;
            avanza;
            gira-izquierda;
            mientras frente-libre hacer inicio
                avanza;
            fin;
            media-vuelta;
        fin;
    fin;

    define-nueva-instruccion virus como inicio
        mientras frente-libre o izquierda-libre hacer inicio
            expandir;
            avanzar;
        fin;
        expandir;
        ir11;
    fin;

    define-nueva-instruccion influenza como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            influenza;
            virus;
        fin;
    fin;

    define-nueva-instruccion juntar(n) como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            juntar(sucede(n));
        fin sino inicio
            si frente-libre o izquierda-libre entonces inicio
                avanzar;
                juntar(0);
            fin sino ir11;
            si no si-es-cero(n) entonces inicio
                deja-zumbador;
            fin;
        fin;
    fin;

    inicia-ejecucion
        este;
        influenza;
        juntar(0);
        apagate;
    termina-ejecucion
finalizar-programa
