iniciar-programa

    define-nueva-instruccion norte como
    inicio
        mientras no-orientado-al-norte hacer
        inicio
            gira-izquierda;
        fin;
    fin;

    define-nueva-instruccion sur como
    inicio
        mientras no-orientado-al-sur hacer
        inicio
            gira-izquierda;
        fin;
    fin;

    define-nueva-instruccion este como
    inicio
        mientras no-orientado-al-este hacer
        inicio
            gira-izquierda;
        fin;
    fin;

    define-nueva-instruccion oeste como
    inicio
        mientras no-orientado-al-oeste hacer
        inicio
            gira-izquierda;
        fin;
    fin;

    define-nueva-instruccion gira-derecha como
    inicio
        repetir 3 veces
        inicio
            gira-izquierda;
        fin;
    fin;

    define-nueva-instruccion gira-doble como
    inicio
        repetir 2 veces
        inicio
            gira-izquierda;
        fin;
    fin;

    define-nueva-instruccion camina como
    inicio
        mientras frente-libre hacer
        inicio
            avanza;
        fin;
    fin;

    define-nueva-instruccion jaja como
    inicio
        si junto-a-zumbador entonces
        inicio
            coge-zumbador;
            si junto-a-zumbador entonces
            inicio
                deja-zumbador;
            fin
            sino
            inicio
                deja-zumbador;
                deja-zumbador;
            fin;
        fin;
    fin;

    define-nueva-instruccion ir como
    inicio
        mientras (no(orientado-al-este y frente-bloqueado)) hacer
        inicio
            si orientado-al-oeste entonces
            inicio
               este;
               si junto-a-zumbador entonces
               inicio
                   jaja;
               fin;
            fin
            sino
            inicio
                avanza;
                si junto-a-zumbador entonces
                inicio
                    jaja;
                fin;
            fin;
        fin;
    fin;

    define-nueva-instruccion regresa como
    inicio
        oeste;
        camina;
    fin;

    define-nueva-instruccion pasa como
    inicio
        norte;
        si frente-libre entonces
        inicio
           avanza;
           oeste;
        fin
        sino
        inicio
            este;
            camina;
        fin;
    fin;

    define-nueva-instruccion zumbadores como
    inicio
        mientras (no((frente-bloqueado y orientado-al-este) y izquierda-bloqueada)) hacer
        inicio
            ir;
            regresa;
            pasa;
        fin;
    fin;

    define-nueva-instruccion volver-a-k como
    inicio
        sur;
        camina;
        oeste;
        camina;
        este;
    fin;

    define-nueva-instruccion revisa(x) como
    inicio
        si junto-a-zumbador entonces
        inicio
           coge-zumbador;
           revisa(sucede(x));
        fin
        sino
        inicio
            repetir x veces
            inicio
                deja-zumbador;
            fin;
            si si-es-cero(precede(precede(x))) entonces
            inicio
                norte;
                si frente-libre entonces
                inicio
                    avanza;
                    si no-junto-a-zumbador entonces
                    inicio
                        deja-zumbador;
                    fin;
                    sur;
                    avanza;
                fin;
                sur;
                si frente-libre entonces
                inicio
                    avanza;
                    si no-junto-a-zumbador entonces
                    inicio
                        deja-zumbador;
                    fin;
                    norte;
                    avanza;
                fin;
                este;
                si frente-libre entonces
                inicio
                    avanza;
                    si no-junto-a-zumbador entonces
                    inicio
                        deja-zumbador;
                    fin;
                    oeste;
                    avanza;
                fin;
                oeste;
                si frente-libre entonces
                inicio
                    avanza;
                    si no-junto-a-zumbador entonces
                    inicio
                        deja-zumbador;
                    fin;
                    este;
                    avanza;
                fin;
            fin;
            este;
        fin;
    fin;

    define-nueva-instruccion ir-2 como
    inicio
        mientras (no(frente-bloqueado y orientado-al-este)) hacer
        inicio
            si orientado-al-oeste entonces
            inicio
               este;
               si junto-a-zumbador entonces
               inicio
                   revisa(0);
               fin;
            fin
            sino
            inicio
                avanza;
                revisa(0);
            fin;
        fin;
    fin;

    define-nueva-instruccion division-celular como
    inicio
        mientras (no((frente-bloqueado y orientado-al-este) y izquierda-bloqueada)) hacer
        inicio
            ir-2;
            regresa;
            pasa;
        fin;
    fin;

    define-nueva-instruccion importante(x) como
    inicio
        si junto-a-zumbador entonces
        inicio
           coge-zumbador;
           importante(sucede(x));
        fin
        sino
        inicio
            repetir x veces
            inicio
                volver-a-k;
                oeste;
                zumbadores;
                volver-a-k;
                oeste;
                division-celular;
            fin;
        fin;
    fin;

    define-nueva-instruccion contar(x) como
    inicio
        si junto-a-zumbador entonces
        inicio
           mientras junto-a-zumbador hacer
           inicio
               coge-zumbador;
           fin;
           contar(sucede(x));
        fin
        sino
        inicio
            si (orientado-al-oeste y frente-bloqueado) entonces
            inicio
               este;
               contar(x);
            fin
            sino
            inicio
                si (orientado-al-este y frente-bloqueado) entonces
                inicio
                   regresa;
                   norte;
                   si frente-libre entonces
                   inicio
                      avanza;
                      oeste;
                      contar(x);
                   fin
                   sino
                   inicio
                       volver-a-k;
                       repetir x veces
                       inicio
                           deja-zumbador;
                       fin;
                       apagate;
                   fin;
                fin
                sino
                inicio
                    si orientado-al-este y frente-libre entonces
                    inicio
                        avanza;
                        contar(x);
                    fin;
                fin;
            fin;
        fin;
    fin;

    inicia-ejecucion
        volver-a-k;
        importante(0);
        volver-a-k;
        oeste;
        contar(0);
        apagate;
    termina-ejecucion
finalizar-programa
