iniciar-programa
    define-nueva-instruccion gira-derecha como inicio
        repetir 3 veces gira-izquierda;
    fin;
    define-nueva-instruccion media-vuelta como inicio
        repetir 2 veces gira-izquierda;
    fin;
    define-nueva-instruccion block como inicio
        si orientado-al-sur y frente-bloqueado entonces media-vuelta;
        si orientado-al-norte y frente-bloqueado entonces inicio
            gira-derecha;
            si frente-libre entonces inicio
                avanza;
                gira-derecha;
            fin
            sino inicio
                media-vuelta;
                mientras frente-libre hacer avanza;
                gira-izquierda;
                mientras frente-libre hacer avanza;
                gira-derecha;
            fin;
        fin;
    fin;
    define-nueva-instruccion asigna como inicio
        mientras no-orientado-al-norte hacer gira-izquierda;
        mientras no-orientado-al-oeste hacer inicio
            si junto-a-zumbador entonces inicio
                coge-zumbador;
                si junto-a-zumbador entonces inicio
                    deja-zumbador;
                fin
                sino inicio
                    repetir 2 veces deja-zumbador;
                fin;
            fin;
            si frente-bloqueado entonces inicio
                block;
            fin
            sino inicio
                avanza;
            fin;
        fin;
    fin;
    define-nueva-instruccion esparce como inicio
        mientras no-orientado-al-norte hacer gira-izquierda;
        mientras no-orientado-al-oeste hacer inicio
            si junto-a-zumbador entonces inicio
                coge-zumbador;
                si junto-a-zumbador entonces inicio
                deja-zumbador;
                si frente-libre entonces inicio
                    avanza;
                    si no-junto-a-zumbador entonces deja-zumbador;
                    media-vuelta;
                    avanza;
                    media-vuelta;
                fin;
                si izquierda-libre entonces inicio
                    gira-izquierda;
                    avanza;
                    si no-junto-a-zumbador entonces deja-zumbador;
                    media-vuelta;
                    avanza;
                    gira-izquierda;
                fin;
                si derecha-libre entonces inicio
                    gira-derecha;
                    avanza;
                    si no-junto-a-zumbador entonces deja-zumbador;
                    media-vuelta;avanza;
                    gira-derecha;
                fin;
                media-vuelta;
                si frente-libre entonces inicio
                    avanza;
                    si no-junto-a-zumbador entonces deja-zumbador;
                    media-vuelta;
                    avanza;
                fin
                sino inicio
                    media-vuelta;
                fin;
                fin
                sino deja-zumbador;
            fin;
            si frente-bloqueado entonces inicio
                block;
            fin
            sino avanza;
        fin;
    fin;
    define-nueva-instruccion contagio como inicio
        coge-zumbador;
        si junto-a-zumbador entonces contagio;
        asigna;
        esparce;
    fin;
    define-nueva-instruccion vacuna como inicio
        mientras no-orientado-al-oeste hacer inicio
            si junto-a-zumbador entonces inicio
                coge-zumbador;
                si junto-a-zumbador entonces inicio
                    vacuna;
                    deja-zumbador;
                fin
                sino deja-zumbador;
            fin;
            si frente-bloqueado entonces inicio
                block;
            fin
            sino avanza;
        fin;
    fin;
    inicia-ejecucion
    si junto-a-zumbador entonces inicio
        mientras no-orientado-al-norte hacer gira-izquierda;
        contagio;
        asigna;
        mientras no-orientado-al-norte hacer gira-izquierda;
        si junto-a-zumbador entonces inicio
            vacuna;
            coge-zumbador;
        fin
        sino vacuna;
    fin;
        apagate;
    termina-ejecucion
finalizar-programa
