iniciar-programa
    define-nueva-instruccion gira (n) como inicio
        repetir n veces
            gira-izquierda;
    fin;
    define-nueva-instruccion norte como inicio
        mientras no-orientado-al-norte hacer
            gira (1);
    fin;
    define-nueva-instruccion sur como inicio
        mientras no-orientado-al-sur hacer
            gira (1);
    fin;
    define-nueva-instruccion este como inicio
        mientras no-orientado-al-este hacer
            gira (1);
    fin;
    define-nueva-instruccion oeste como inicio
        mientras no-orientado-al-oeste hacer
            gira (1);
    fin;
    define-nueva-instruccion rodea como inicio
        norte;
        si frente-libre entonces inicio
            avanza;
            si no-junto-a-zumbador entonces inicio
                deja-zumbador;
            fin;
            sur;
            avanza;
        fin;
        sur;
        si frente-libre entonces inicio
            avanza;
            si no-junto-a-zumbador entonces inicio
                deja-zumbador;
            fin;
            norte;
            avanza;
        fin;
        este;
        si frente-libre entonces inicio
            avanza;
            si no-junto-a-zumbador entonces inicio
                deja-zumbador;
            fin;
            oeste;
            avanza;
        fin;
        oeste;
        si frente-libre entonces inicio
            avanza;
            si no-junto-a-zumbador entonces inicio
                deja-zumbador;
            fin;
            este;
            avanza;
        fin;
        norte;
    fin;
    define-nueva-instruccion dosis como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            si junto-a-zumbador entonces inicio
                deja-zumbador;
                rodea;
            fin
            sino inicio
                deja-zumbador;
            fin;
        fin;
    fin;
    define-nueva-instruccion aumenta como inicio
        mientras frente-libre y no-junto-a-zumbador hacer
            avanza;
        si junto-a-zumbador entonces inicio
            dosis;
            si frente-libre entonces inicio
                avanza;
                aumenta;
            fin
            sino inicio
                si frente-bloqueado y derecha-libre entonces inicio
                    sur;
                    mientras frente-libre hacer
                        avanza;
                    este;
                    avanza;
                    norte;
                    aumenta;
                fin;
            fin;
        fin;
        si frente-bloqueado y derecha-libre entonces inicio
            sur;
            mientras frente-libre hacer
                avanza;
            este;
            avanza;
            norte;
            aumenta;
        fin;
    fin;
    define-nueva-instruccion recorre como inicio
        mientras frente-libre y no-junto-a-zumbador hacer
            avanza;
        si junto-a-zumbador entonces inicio
            mientras junto-a-zumbador hacer
                coge-zumbador;
            repetir 2 veces
                deja-zumbador;
            si frente-libre entonces inicio
                avanza;
                recorre;
            fin
            sino inicio
                si frente-bloqueado y derecha-libre entonces inicio
                    sur;
                    mientras frente-libre hacer
                        avanza;
                    este;
                    avanza;
                    norte;
                    recorre;
                fin;
            fin;
        fin
        sino inicio
            si frente-bloqueado y derecha-libre entonces inicio
                sur;
                mientras frente-libre hacer
                    avanza;
                este;
                avanza;
                norte;
                recorre;
            fin;
        fin;
    fin;
    define-nueva-instruccion orienta como inicio
        sur;
        mientras frente-libre hacer
            avanza;
        oeste;
        mientras frente-libre hacer
            avanza;
        norte;
    fin;
    define-nueva-instruccion checa (n) como inicio
        mientras frente-libre y no-junto-a-zumbador hacer
            avanza;
        si junto-a-zumbador entonces inicio
            mientras junto-a-zumbador hacer
                coge-zumbador;
            checa(sucede(n));
        fin
        sino inicio
            si frente-bloqueado y derecha-libre entonces inicio
                sur;
                mientras frente-libre hacer
                    avanza;
                este;
                avanza;
                norte;
                checa(n);
            fin;
        fin;
        orienta;
        repetir n veces
            deja-zumbador;
        apagate;
    fin;
    define-nueva-instruccion influenza (n) como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            influenza(sucede(n));
        fin
        sino inicio
            repetir n veces inicio
                recorre;
                orienta;
                aumenta;
                orienta;
            fin;
        fin;
    fin;
    inicia-ejecucion
        influenza(0);
        checa(0);
        apagate;
    termina-ejecucion
finalizar-programa