iniciar-programa
define-nueva-instruccion gira(t) como inicio
    repetir t veces
        gira-izquierda;
fin;
define-nueva-instruccion vuelta1 como inicio
    si derecha-libre entonces inicio
        mientras derecha-libre hacer inicio
	    gira(3);
            avanza;
	fin;
        si junto-a-zumbador entonces sal-de-instruccion;
        deja-zumbador;
        vuelta1;
    fin
    sino inicio
        si frente-libre entonces inicio
            avanza;
            si derecha-bloqueada entonces
                si junto-a-zumbador entonces sal-de-instruccion;
            si derecha-bloqueada entonces deja-zumbador;
            vuelta1;
        fin
        sino inicio
            si izquierda-libre entonces inicio
                gira(1);
                avanza;
                si derecha-bloqueada y junto-a-zumbador entonces sal-de-instruccion;
                deja-zumbador;
                vuelta1;
            fin
            sino gira(2);
        fin;
    fin;
fin;
define-nueva-instruccion checa como inicio
    si no orientado-al-sur entonces inicio
        gira(1);
        checa;
        gira(3);
    fin
    sino inicio
        si frente-libre entonces inicio
            avanza;
            checa;
            avanza;
        fin
        sino inicio
            si junto-a-zumbador entonces inicio
                gira(2);
            fin
            sino inicio
                gira(3);
                mientras frente-libre hacer avanza;
                apagate;
            fin;
        fin;
    fin;
fin;
define-nueva-instruccion vuelta2 como inicio
    si derecha-libre entonces inicio
        gira(3);
        avanza;
        checa;
        gira(2);
    fin
    sino inicio
        si frente-libre entonces inicio
            avanza;
            checa;
            gira(2);
        fin
        sino inicio
            gira(1);
            si frente-libre entonces inicio
                avanza;
                checa;
                gira(2);
            fin
            sino inicio
                gira(1);
                avanza;
                checa;
                gira(2);
            fin;
        fin;
    fin;
    vuelta2;
fin;
    inicia-ejecucion
    mientras derecha-libre hacer gira(3);
    vuelta1;
    vuelta2;
        apagate;
    termina-ejecucion
finalizar-programa
 