iniciar-programa
    define-nueva-instruccion gira(n) como inicio
        repetir n veces gira-izquierda;
    fin;
    define-nueva-instruccion avanzar como inicio
        si (frente-libre y izquierda-bloqueada) entonces inicio
            avanza;
        fin sino inicio
            si izquierda-libre entonces inicio
                gira(1);
                avanza;
            fin sino inicio
                gira(3);
                avanza;
            fin;
        fin;
    fin;
    define-nueva-instruccion margen como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            si junto-a-zumbador entonces inicio
                sal-de-instruccion;
            fin sino inicio
                deja-zumbador;
                avanzar;
                margen;
            fin;
        fin sino inicio
            deja-zumbador;
            avanzar;
            margen;
        fin;
    fin;
    define-nueva-instruccion linea como inicio
        mientras junto-a-zumbador hacer inicio
            avanzar;
            si izquierda-bloqueada entonces inicio
                gira(3);
                mientras frente-libre hacer avanza;
                si no-junto-a-zumbador entonces sal-de-instruccion;
                gira(2);
                mientras frente-libre hacer avanza;
                gira(3);
             fin;
        fin;
    fin;
    define-nueva-instruccion llegacasa como inicio
        si orientado-al-norte entonces inicio
            gira(1);
            mientras frente-libre hacer avanza;
            gira(1);
            mientras frente-libre hacer avanza;
        fin sino inicio
            mientras no-orientado-al-sur hacer gira(1);
            mientras frente-libre hacer avanza;
            mientras no-orientado-al-oeste hacer gira(1);
            mientras frente-libre hacer avanza;
        fin;
    fin;
    inicia-ejecucion
        mientras izquierda-libre hacer gira(1);
        repetir 2 veces deja-zumbador;
        mientras junto-a-zumbador hacer avanzar;
        margen;
        linea;
        llegacasa;
        apagate;
    termina-ejecucion
finalizar-programa