iniciar-programa

    define-nueva-instruccion norte como mientras no orientado-al-norte hacer gira-izquierda;
    define-nueva-instruccion sur como mientras no orientado-al-sur hacer gira-izquierda;
    define-nueva-instruccion este como mientras no orientado-al-este hacer gira-izquierda;
    define-nueva-instruccion oeste como mientras no orientado-al-oeste hacer gira-izquierda;

    define-nueva-instruccion revisa como inicio
        norte;
        si frente-libre entonces inicio
            avanza;
            oeste;
            si frente-libre entonces inicio
                avanza;
                si no junto-a-zumbador entonces inicio
                    este;
                    avanza;
                    sur;
                fin sino inicio
                    este;
                    avanza;
                    norte;
                fin;
            fin sino inicio
                sur;
            fin;
            si orientado-al-sur entonces inicio
                este;
                si frente-libre entonces inicio
                    avanza;
                    si no junto-a-zumbador entonces inicio
                        oeste;
                        avanza;
                        sur;
                    fin sino inicio
                        oeste;
                        avanza;
                        norte;
                    fin;
                fin sino inicio
                    sur;
                fin;
            fin sino inicio
                norte
            fin;
        fin sino inicio
            sur;
        fin;
        si orientado-al-sur entonces inicio
            avanza;
            apagate;
        fin sino inicio
            sur;
            avanza;
        fin;
    fin;

    define-nueva-instruccion busqueda(n) como inicio
        si junto-a-zumbador y no si-es-cero(n) entonces inicio
            coge-zumbador;
            si junto-a-zumbador entonces inicio
                coge-zumbador;
                si junto-a-zumbador entonces inicio
                    repetir 3 veces deja-zumbador;
                fin sino inicio
                    revisa;
                    repetir 3 veces deja-zumbador;
                    norte;
                    si frente-libre entonces inicio
                        avanza;
                        este;
                        si frente-libre entonces inicio
                            avanza;
                            busqueda(precede(n));
                            oeste;
                            avanza;
                        fin;
                        oeste;
                        si frente-libre entonces inicio
                            avanza;
                            busqueda(precede(n));
                            este;
                            avanza;
                        fin;
                        sur;
                        avanza;
                    fin;
                    coge-zumbador;
                fin;
            fin sino inicio
                repetir 3 veces deja-zumbador;
                si orientado-al-este entonces inicio
                    norte;
                    si frente-libre entonces inicio
                        avanza;
                        este;
                        si frente-libre entonces inicio
                            avanza;
                            busqueda(n);
                        fin;
                        oeste;
                        avanza;
                        sur;
                        avanza;
                    fin;
                fin sino inicio
                    si orientado-al-oeste entonces inicio
                        norte;
                        avanza;
                        oeste;
                        si frente-libre entonces inicio
                            avanza;
                            busqueda(n);
                        fin;
                        este;
                        avanza;
                        sur;
                        avanza;
                    fin;
                fin;
                repetir 2 veces coge-zumbador;
            fin;
        fin;
    fin;

    define-nueva-instruccion infinito(n) como inicio
        si junto-a-zumbador o no junto-a-zumbador entonces inicio
            busqueda(n);
            infinito(sucede(n));
        fin;
    fin;

    inicia-ejecucion
        infinito(1);
        apagate;
    termina-ejecucion
finalizar-programa
