iniciar-programa
    define-nueva-instruccion norte como mientras no orientado-al-norte hacer gira-izquierda;
    define-nueva-instruccion oeste como mientras no orientado-al-oeste hacer gira-izquierda;
    define-nueva-instruccion este como mientras no orientado-al-este hacer gira-izquierda;
    define-nueva-instruccion sur como mientras no orientado-al-sur hacer gira-izquierda;

    define-nueva-instruccion pueblo como inicio
        mientras no junto-a-zumbador hacer inicio
            este;
            avanza;
            norte;
            avanza;
            coge-zumbador;
        fin;
    fin;

    define-nueva-instruccion pueblo2 como inicio
        mientras no junto-a-zumbador hacer inicio
            oeste;
            avanza;
            norte;
            avanza;
            coge-zumbador;
        fin;
    fin;

    define-nueva-instruccion marcar como inicio
        mientras no junto-a-zumbador hacer inicio
            deja-zumbador;
            sur;
            avanza;
            oeste;
            avanza;
        fin;
    fin;

    define-nueva-instruccion marcar2 como inicio
        mientras no junto-a-zumbador hacer inicio
            deja-zumbador;
            sur;
            avanza;
            este;
            avanza;
        fin;
    fin;

    define-nueva-instruccion revisa como inicio
        norte;
        avanza;
        este;
        avanza;
        si junto-a-zumbador entonces inicio
            sur;
            avanza;
            oeste;
            avanza;
        fin sino inicio
            sur;
            avanza;
            oeste;
            avanza;
            apagate;
        fin;
    fin;

    define-nueva-instruccion camino(n) como inicio
        si si-es-cero(n) entonces inicio
            revisa;
        fin;
        este;
        si no si-es-cero(n) entonces inicio
            avanza;
            norte;
            avanza;
            coge-zumbador;
            pueblo;
            camino(precede(n));
            deja-zumbador;
            sur;
            avanza;
            oeste;
            avanza;
            marcar;
        fin;
        oeste;
        si no si-es-cero(n) entonces inicio
            avanza;
            norte;
            avanza;
            coge-zumbador;
            pueblo2;
            camino(precede(n));
            deja-zumbador;
            sur;
            avanza;
            este;
            avanza;
            marcar2;
        fin;
    fin;

    define-nueva-instruccion buscar(n) como inicio
        camino(n);
        buscar(sucede(n));
    fin;

    inicia-ejecucion
        buscar(0);
        apagate;
    termina-ejecucion
finalizar-programa
