iniciar-programa

    define-nueva-instruccion este como
        mientras no-orientado-al-este hacer
            gira-izquierda;

    define-nueva-instruccion oeste como
        mientras no-orientado-al-oeste hacer
            gira-izquierda;

    define-nueva-instruccion sur como
        mientras no-orientado-al-sur hacer
            gira-izquierda;

    define-nueva-instruccion norte como
        mientras no-orientado-al-norte hacer
            gira-izquierda;

    define-nueva-instruccion cambiar como inicio
        norte;
        si frente-libre entonces inicio
            avanza;
            este;
            mientras frente-libre hacer
                avanza;
        fin;
    fin;

    define-nueva-instruccion ir_esquina como inicio
        este;
        mientras no-orientado-al-sur hacer inicio
            mientras derecha-bloqueada y frente-libre hacer
                avanza;
            sur;
            si frente-libre entonces inicio
                avanza;
                este;
            fin;
        fin;
    fin;

    define-nueva-instruccion sumar (n) como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            sumar (sucede (n));
            deja-zumbador;
        fin
        sino inicio
            repetir n veces
                deja-zumbador;
            gira-izquierda;
            gira-izquierda;
            avanza;
        fin;
    fin;

    define-nueva-instruccion procesar como inicio
        sur;
        si frente-libre entonces inicio
            avanza;
            sumar (0);
        fin;
        este;
        si frente-libre entonces inicio
            avanza;
            sumar(0);
        fin;
        oeste;
    fin;

    define-nueva-instruccion cuenta como inicio
        mientras no-orientado-al-norte hacer inicio
            procesar;
            si frente-libre entonces inicio
                avanza;
            fin
            sino inicio
                cambiar;
            fin;
            mientras junto-a-zumbador y no-orientado-al-norte hacer
                coge-zumbador;
        fin;
    fin;

    define-nueva-instruccion lleva como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            lleva;
            deja-zumbador;
        fin
        sino inicio
            ir_esquina;
            mientras junto-a-zumbador hacer
                coge-zumbador;
        fin;
    fin;

    inicia-ejecucion
        ir_esquina;
        deja-zumbador;
        cuenta;
        lleva;
        apagate;
    termina-ejecucion
finalizar-programa