iniciar-programa
define-nueva-instruccion gira-derecha como
inicio
    repetir 3 veces
      gira-izquierdA;
fin;
define-nueva-instruccion paso-atras como
inicio
   repetir 2 veces
      gira-izquierdA;
   avanza;
   repetir 2 veces
     gira-izquierdA;
fin;
define-nueva-instruccion mira-este como
inicio
   mientras no-orientado-al-este hacer
     gira-izquierda;
fin;
define-nueva-instruccion mira-oeste como
inicio
   mientras no-orientado-al-oeste hacer
     gira-izquierda;
fin;
define-nueva-instruccion mira-sur como
inicio
    mientras no-orientado-al-sur hacer
       gira-izquierda;
fin;
define-nueva-instruccion mira-norte como
inicio
   mientras no-orientado-al-norte hacer
     gira-izquierda;
fin;
define-nueva-instruccion abajo como
inicio
    mira-este;
    mientras orientado-al-este hacer
    inicio
       mientras derecha-bloqueada y frente-libre hacer
         avanza;
      si derecha-libre entonces
      inicio
         gira-derecha;
         avanza;
         gira-izquierda;
      fin
      sino
         mira-oeste;
    fin;
fin;
define-nueva-instruccion arriba como
inicio
    mira-oeste;
    mientras orientado-al-oeste hacer
    inicio
        mientras derecha-bloqueada y frente-libre hacer
            avanzA;
        si derecha-libre entonces
        inicio
           gira-derecha;
           avanza;
           gira-izquierda;
        fin
        sino
            mira-este;
    fin;
fin;
define-nueva-instruccion limpia como
inicio
    mira-oeste;
    mientras orientado-al-oeste hacer
    inicio
        mientras frente-libre hacer
        inicio
           mientras junto-a-zumbador hacer
             coge-zumbador;
           avanza;
        fin;
        mientras junto-a-zumbador hacer
             coge-zumbador;
        mira-este;
        mientras frente-libre hacer
          avanza;
        mira-oeste;
        mientras derecha-bloqueada y frente-libre hacer
        inicio
           avanza;
        fin;
        si derecha-libre entonces
        inicio
           gira-derecha;
           avanza;
           gira-izquierda;
        fin
        sino
           mira-este;
    fin;
fin;
define-nueva-instruccion deja(n) como
inicio
   si junto-a-zumbador entonces
   inicio
       coge-zumbador;
       deja(sucede(n));
       deja-zumbador;
   fin
   sino
   inicio
       repetir n veces
          deja-zumbador;
       avanza;
   fin;
fin;
define-nueva-instruccion tabla como
inicio
    mira-oeste;
    mientras no-junto-a-zumbador hacer
    inicio
        si izquierda-libre entonces
        inicio
           gira-derecha;
           paso-atras;
           deja(0);
           gira-izquierdA;
        fin;
        repetir 2 veces
           gira-izquierda;
        si frente-libre entonces
        inicio
           avanza;
           repetir 2 veces
             gira-izquierda;
           deja(0);
        fin
        sino
        inicio
            repetir 2 veces
               gira-izquierda;
        fin;
        si frente-libre entonces
          avanza
        sino
        inicio
            gira-derecha;
            avanza;
            mira-este;
            mientras frente-libre hacer
              avanza;
            mira-oeste;
        fin;
    fin;
fin;
define-nueva-instruccion recoge(n) como
inicio
    si junto-a-zumbador entonces
    inicio
        coge-zumbador;
        recoge(sucede(n));
    fin
    sino
    inicio
        abajo;
        mientras junto-a-zumbador hacer
           coge-zumbador;
        repetir n veces
           deja-zumbador;
    fin;
fin;
    inicia-ejecucion
    abajo;
    limpia;
    repetir 2 veces
      deja-zumbador;
    abajo;
    mira-norte;
    deja-zumbador;
    mira-oeste;
    si frente-libre entonces
       avanza
    sino
    inicio
       mira-norte;
       avanza;
    fin;
    tabla;
    repetir 2 veces
      coge-zumbador;
    si izquierda-libre entonces
        inicio
           gira-derecha;
           paso-atras;
           deja(0);
           gira-izquierdA;
        fin;
        repetir 2 veces
           gira-izquierda;
        si frente-libre entonces
        inicio
           avanza;
           repetir 2 veces
             gira-izquierda;
           deja(0);
        fin
        sino
        inicio
            repetir 2 veces
               gira-izquierda;
        fin;
     recoge(0);
        apagate;
    termina-ejecucion
finalizar-programa
