iniciar-programa
    define-nueva-instruccion norte como inicio
        mientras no-orientado-al-norte hacer inicio
            gira-izquierda;
        fin;
    fin;
    define-nueva-instruccion sur como inicio
        mientras no-orientado-al-sur hacer inicio
            gira-izquierda;
        fin;
    fin;
    define-nueva-instruccion este como inicio
        mientras no-orientado-al-este hacer inicio
            gira-izquierda;
        fin;
    fin;
    define-nueva-instruccion oeste como inicio
        mientras no-orientado-al-oeste hacer inicio
            gira-izquierda;
        fin;
    fin;
    define-nueva-instruccion avanzaquita como inicio
        mientras junto-a-zumbador hacer inicio
            coge-zumbador;
        fin;
        si frente-libre entonces inicio
            avanza;
        fin;
    fin;
    define-nueva-instruccion quitar como inicio
    mientras no-orientado-al-norte hacer inicio
        este;
        mientras frente-libre hacer inicio
            avanzaquita;
        fin;
        si frente-bloqueado y junto-a-zumbador entonces inicio
            mientras junto-a-zumbador hacer inicio
                coge-zumbador;
            fin;
        fin;
        oeste;
        mientras izquierda-bloqueada y frente-libre  hacer inicio
            avanza;
        fin;
        si frente-bloqueado y izquierda-bloqueada entonces inicio
            este;
            mientras frente-libre hacer inicio
                avanzaquita;
            fin;
            norte;
            sal-de-instruccion;
        fin;
        sur;
        avanza;
        oeste;
        mientras frente-libre hacer inicio
            avanza;
        fin;
    fin;
    fin;
    define-nueva-instruccion marcar-escuela como inicio
       este;
       mientras frente-libre o derecha-libre hacer inicio
           mientras derecha-bloqueada y frente-libre hacer inicio
               avanza;
           fin;
           si derecha-libre entonces inicio
               sur;
               avanza;
               este;
           fin;
       fin;
       oeste;
       repetir 2 veces inicio
           deja-zumbador;
       fin;
    fin;
    define-nueva-instruccion volver como inicio
       este;
       mientras frente-libre o derecha-libre hacer inicio
           mientras derecha-bloqueada y frente-libre hacer inicio
               avanza;
           fin;
           si derecha-libre entonces inicio
               sur;
               avanza;
               este;
           fin;
       fin;
       oeste;
       repetir 2 veces inicio
           coge-zumbador;
       fin;
    fin;
    define-nueva-instruccion regresar como inicio
       oeste;
       mientras frente-libre o derecha-libre hacer inicio
           mientras derecha-bloqueada y frente-libre hacer inicio
               avanza;
           fin;
           si derecha-libre entonces inicio
               norte;
               avanza;
               oeste;
           fin;
       fin;
    fin;
    define-nueva-instruccion rutas como inicio
        si junto-a-zumbador entonces inicio
            deja-zumbador;
        fin sino inicio
            deja-zumbador;
            este;
            si frente-libre entonces inicio
                avanza;
                rutas;
                oeste;
                avanza;
            fin;
            sur;
            si frente-libre entonces inicio
                avanza;
                rutas;
                norte;
                avanza;
            fin;
            coge-zumbador;
        fin;
    fin;
    define-nueva-instruccion acomodar(n) como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            acomodar(sucede(n));
        fin sino inicio
            este;
            mientras frente-libre hacer inicio
                avanza;
            fin;
            repetir n veces inicio
                deja-zumbador;
            fin;
        fin;
    fin;
    inicia-ejecucion
        este;
        quitar;
        regresar;
        marcar-escuela;
        regresar;
        rutas;
        volver;
        acomodar(0);
        apagate;
    termina-ejecucion
finalizar-programa
