iniciar-programa

    define-nueva-instruccion norte como mientras no orientado-al-norte hacer gira-izquierda;
    define-nueva-instruccion sur como mientras no orientado-al-sur hacer gira-izquierda;
    define-nueva-instruccion este como mientras no orientado-al-este hacer gira-izquierda;
    define-nueva-instruccion oeste como mientras no orientado-al-oeste hacer gira-izquierda;

    define-nueva-instruccion regresa como inicio
        mientras no orientado-al-este hacer inicio
            si frente-libre entonces inicio
                avanza;
            fin sino inicio
                norte;
                si frente-libre entonces inicio
                    avanza;
                    oeste;
                fin sino inicio
                    este;
                fin;
            fin;
        fin;
    fin;

    define-nueva-instruccion marca como inicio
        mientras no orientado-al-oeste hacer inicio
            si frente-libre entonces inicio
                mientras junto-a-zumbador hacer coge-zumbador;
                avanza;
            fin sino inicio
                sur;
                mientras junto-a-zumbador hacer coge-zumbador;
                si frente-libre entonces inicio
                    avanza;
                    oeste;
                    mientras frente-libre hacer avanza;
                    este;
                fin sino inicio
                    oeste;
                fin;
            fin;
        fin;
        mientras derecha-bloqueada y frente-libre hacer avanza;
        deja-zumbador;
        regresa;
    fin;

    define-nueva-instruccion dejar como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            dejar;
            deja-zumbador;
        fin sino inicio
            este;
            mientras frente-libre hacer avanza;
        fin;
    fin;

    define-nueva-instruccion final como inicio
        mientras no orientado-al-oeste hacer inicio
            si frente-libre entonces inicio
                avanza;
            fin sino inicio
                sur;
                si frente-libre entonces inicio
                    avanza;
                    este;
                fin sino inicio
                    oeste;
                    mientras derecha-bloqueada y frente-libre hacer avanza;
                    coge-zumbador;
                    dejar;
                    apagate;
                fin;
            fin;
        fin;
    fin;

    define-nueva-instruccion busqueda como inicio
        si no junto-a-zumbador entonces inicio
            deja-zumbador;
            este;
            si frente-libre entonces inicio
                avanza;
                si junto-a-zumbador entonces inicio
                    deja-zumbador;
                    oeste;
                    avanza;
                fin sino inicio
                    busqueda;
                    oeste;
                    avanza;
                fin;
            fin;
            sur;
            si frente-libre entonces inicio
                avanza;
                si junto-a-zumbador entonces inicio
                    deja-zumbador;
                    norte;
                    avanza;
                fin sino inicio
                    busqueda;
                    norte;
                    avanza;
                fin;
            fin;
            coge-zumbador;
        fin;
    fin;

    inicia-ejecucion
        este;
        mientras frente-libre hacer avanza;
        si frente-bloqueado y derecha-bloqueada y izquierda-bloqueada entonces inicio
            deja-zumbador;
            apagate;
        fin;
        oeste;
        mientras frente-libre hacer avanza;
        este;
        marca;
        busqueda;
        este;
        final;
        apagate;
    termina-ejecucion
finalizar-programa
