iniciar-programa

define-nueva-instruccion norte como mientras no-orientado-al-norte hacer gira-izquierda;
define-nueva-instruccion este como mientras no-orientado-al-este hacer gira-izquierda;
define-nueva-instruccion oeste como mientras no-orientado-al-oeste hacer gira-izquierda;
define-nueva-instruccion sur como mientras no-orientado-al-sur hacer gira-izquierda;

    define-nueva-instruccion avanzar como inicio
        este;
        si frente-libre entonces inicio
            avanza;
        fin sino inicio
            oeste;
            mientras frente-libre hacer inicio
                avanza;
            fin;
            este;
            mientras frente-libre y derecha-bloqueada hacer inicio
                avanza;
            fin;
            sur;
            si frente-libre entonces inicio
                avanza;
                oeste;
                mientras frente-libre hacer inicio
                    avanza;
                fin;
                este;
            fin;
        fin;
        mientras junto-a-zumbador y no-orientado-al-sur hacer inicio
            coge-zumbador;
        fin;
    fin;

    define-nueva-instruccion clon(x) como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            clon(sucede(x));
            deja-zumbador;
        fin sino inicio
            repetir x veces deja-zumbador;
            repetir 2 veces gira-izquierda;
            avanza;
        fin;
    fin;

    define-nueva-instruccion copiar como inicio
        norte;
        si frente-libre entonces inicio
            avanza;
            clon(0);
        fin;

        oeste;
        si frente-libre entonces inicio
            avanza;
            clon(0);
        fin;
    fin;

    inicia-ejecucion
        este;
        mientras junto-a-zumbador hacer inicio
            coge-zumbador;
        fin;
        deja-zumbador;
        mientras no-orientado-al-sur hacer inicio
            copiar;
            avanzar;
        fin;
        apagate;
    termina-ejecucion
finalizar-programa
