iniciar-programa
define-nueva-instruccion sur como
    mientras no orientado-al-sur hacer gira-izquierda;
define-nueva-instruccion este como
    mientras no orientado-al-este hacer gira-izquierda;
define-nueva-instruccion norte como
    mientras no orientado-al-norte hacer gira-izquierda;
define-nueva-instruccion oeste como
    mientras no orientado-al-oeste hacer gira-izquierda;
define-nueva-instruccion derecha como
    repetir 3 veces gira-izquierda;

define-nueva-instruccion irinicio como inicio
    mientras frente-libre o derecha-libre hacer inicio
        mientras derecha-bloqueada y frente-libre hacer inicio
            avanza;
        fin;
        si derecha-libre entonces inicio
            norte;
            si frente-libre entonces avanza;
            oeste;
        fin;
    fin;
fin;
define-nueva-instruccion quitar como inicio
    este;
    mientras frente-libre o derecha-libre  hacer inicio
        mientras junto-a-zumbador hacer coge-zumbador;
        si frente-libre entonces avanza;
        si frente-bloqueado y derecha-libre entonces inicio
            derecha;
            mientras junto-a-zumbador hacer coge-zumbador;
            avanza;
            oeste;
            mientras frente-libre hacer avanza;
            este;
        fin;
    fin;
    si junto-a-zumbador entonces inicio
        mientras junto-a-zumbador hacer coge-zumbador;
    fin;
fin;

define-nueva-instruccion camino como inicio
    este;
    mientras frente-libre o derecha-libre hacer inicio
        mientras derecha-bloqueada y frente-libre hacer inicio
            avanza;
        fin;
        si derecha-libre entonces inicio
            sur;
            avanza;
            este;
        fin;
    fin;
    oeste;
    mientras derecha-bloqueada y frente-libre hacer inicio
        avanza;
    fin;
fin;
define-nueva-instruccion contarar(a)como inicio
    si junto-a-zumbador entonces inicio
        coge-zumbador;
        contarar(sucede(a));
        deja-zumbador;
    fin sino inicio
        este;
        mientras frente-libre hacer avanza;
        mientras  junto-a-zumbador hacer coge-zumbador;
    fin;
fin;
define-nueva-instruccion contar como inicio
    camino;
    contarar(0);
fin;
define-nueva-instruccion buscar como inicio
    si junto-a-zumbador entonces inicio
        deja-zumbador;
    fin sino inicio
        deja-zumbador;
        este;
        si frente-libre entonces inicio
            avanza;
            buscar;
            oeste;
            avanza;
        fin;
        sur;
        si frente-libre entonces inicio
            avanza;
            buscar;
            norte;
            avanza;
        fin;
        coge-zumbador;
    fin;
fin;
    inicia-ejecucion
    quitar;
    irinicio;
    camino;
    repetir 2 veces deja-zumbador;
    irinicio;
    buscar;
    contar;
    repetir 2 veces coge-zumbador;                      
        apagate;
    termina-ejecucion
finalizar-programa
