iniciar-programa

    define-nueva-instruccion gira(n) como inicio
        repetir n veces gira-izquierda;
    fin;

    define-nueva-instruccion norte como inicio
        mientras no-orientado-al-norte hacer gira-izquierda;
    fin;

    define-nueva-instruccion sur como inicio
        mientras no-orientado-al-sur hacer gira-izquierda;
    fin;

    define-nueva-instruccion este como inicio
        mientras no-orientado-al-este hacer gira-izquierda;
    fin;

    define-nueva-instruccion oeste como inicio
        mientras no-orientado-al-oeste hacer gira-izquierda;
    fin;

    define-nueva-instruccion sumanorte(n) como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            sumanorte(sucede(n));
            deja-zumbador;
        fin sino inicio
            repetir n veces deja-zumbador;
            sur;
            avanza;
        fin;
    fin;

    define-nueva-instruccion sumaoeste(n) como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            sumaoeste(sucede(n));
            deja-zumbador;
        fin sino inicio
            repetir n veces deja-zumbador;
            este;
            avanza;
        fin;
    fin;



    define-nueva-instruccion busca como inicio
        mientras frente-libre o no-orientado-al-sur hacer inicio
            norte;
            si frente-libre o izquierda-libre entonces inicio
                mientras junto-a-zumbador hacer coge-zumbador;
            fin;
            si frente-libre entonces inicio
                avanza;
                sumanorte(0);
            fin;

            oeste;
            si frente-libre entonces inicio
                avanza;
            sumaoeste(0);
            fin;
            este;
            si frente-libre entonces inicio
                avanza;
            fin sino inicio
                oeste;
                mientras frente-libre hacer avanza;
                este;
                mientras (derecha-bloqueada y frente-libre) hacer avanza;
                sur;
                si frente-libre entonces inicio
                    avanza;
                    este;
                fin;
            fin;
        fin;
    fin;




    inicia-ejecucion
        mientras junto-a-zumbador hacer coge-zumbador;
        deja-zumbador;
        este;
        busca;
        apagate;
    termina-ejecucion
finalizar-programa
