iniciar-programa

define-nueva-instruccion gira(n) como repetir n veces gira-izquierda;

define-nueva-instruccion sumar(a) como inicio
    si junto-a-zumbador entonces inicio
        coge-zumbador;
        sumar(sucede(a));
    fin sino inicio
        repetir a veces deja-zumbador;
        gira(2);
        avanza;
        gira(2);
        repetir a veces deja-zumbador;
    fin;
fin;

define-nueva-instruccion camino como inicio
    mientras frente-libre o no-junto-a-zumbador hacer inicio
        si izquierda-libre entonces inicio
            gira(1);
            avanza;
            sumar(0);
            gira(3);
            gira(2);
            si frente-libre entonces inicio
                avanza;
                sumar(0);
            fin;
            gira(2);
        fin sino inicio
            gira(2);
            si frente-libre entonces inicio
                avanza;
                sumar(0);
            fin;
            gira(2);
        fin;
        si frente-libre entonces inicio
            avanza;
            mientras junto-a-zumbador hacer coge-zumbador;
        fin;
    fin;
    gira(2);
    mientras frente-libre hacer avanza;
    gira(2);
    mientras derecha-bloqueada y frente-libre hacer avanza;
    si derecha-libre entonces inicio
        gira(3);
        avanza;
        gira(1);
        mientras junto-a-zumbador hacer coge-zumbador;
        camino;
    fin;
fin;

    inicia-ejecucion

    mientras no-orientado-al-este hacer gira(1);
    mientras junto-a-zumbador hacer coge-zumbador;
    deja-zumbador;
    camino;


        apagate;
    termina-ejecucion
finalizar-programa
