iniciar-programa

    define-nueva-instruccion norte como inicio
        mientras no-orientado-al-norte hacer inicio
            gira-izquierda;
        fin;
    fin;
    define-nueva-instruccion este como inicio
        mientras no-orientado-al-este hacer inicio
            gira-izquierda;
        fin;
    fin;
    define-nueva-instruccion oeste como inicio
        mientras no-orientado-al-oeste hacer inicio
            gira-izquierda;
        fin;
    fin;
    define-nueva-instruccion sur como inicio
        mientras no-orientado-al-sur hacer inicio
            gira-izquierda;
        fin;
    fin;

    define-nueva-instruccion recoger como inicio
    mientras no orientado-al-oeste hacer inicio
        mientras junto-a-zumbador hacer inicio
            coge-zumbador;
        fin;
        mientras frente-libre hacer inicio
            avanza;
            mientras junto-a-zumbador hacer inicio
                coge-zumbador;
            fin
        fin;
        oeste;
        mientras frente-libre y izquierda-bloqueada hacer inicio
            avanza;
        fin;
        sur;
        si frente-libre entonces inicio
            avanza;
            oeste;
            mientras frente-libre hacer inicio
                avanza;
            fin;
            este;
        fin sino inicio
            oeste;
        fin;
        fin;
    fin;



    define-nueva-instruccion buscar como inicio
        si junto-a-zumbador entonces inicio
            deja-zumbador
        fin sino inicio
            deja-zumbador;
            este;
            si frente-libre entonces inicio
                avanza;
                buscar;
                oeste;
                avanza;
            fin;
            sur;
            si frente-libre entonces inicio
                avanza;
                buscar;
                norte;
                avanza;
            fin;
            coge-zumbador;
        fin;
    fin;
    define-nueva-instruccion regresar como inicio
        oeste;
        mientras frente-libre o derecha-libre hacer inicio
            mientras derecha-bloqueada y frente-libre hacer inicio
                avanza;
            fin;
            si derecha-libre entonces inicio
                norte;
                avanza;
                oeste;
            fin;
        fin;
    fin;

    define-nueva-instruccion salida como inicio
        este;
        mientras orientado-al-este hacer inicio
            mientras frente-libre y derecha-bloqueada hacer inicio
                avanza;
            fin;
            sur;
            si frente-libre entonces inicio
                avanza;
                este;
            fin;
        fin;
        repetir 2 veces coge-zumbador;
    fin;

    inicia-ejecucion
        este;
        recoger;
        este;
        mientras frente-libre hacer inicio
            avanza;
        fin;
        repetir 2 veces deja-zumbador;
        regresar;
        buscar;
        salidA;
        apagate;
    termina-ejecucion
finalizar-programa

