iniciar-programa

    define-nueva-instruccion norte como
        mientras no-orientado-al-norte hacer
            gira-izquierda;

    define-nueva-instruccion sur como
        mientras no-orientado-al-sur hacer
            gira-izquierda;

    define-nueva-instruccion este como
        mientras no-orientado-al-este hacer
            gira-izquierda;

    define-nueva-instruccion oeste como
        mientras no-orientado-al-oeste hacer
            gira-izquierda;


    define-nueva-instruccion dejar (n) como
        repetir n veces
            deja-zumbador;

    define-nueva-instruccion avanzar (n) como inicio
        repetir n veces inicio
            si frente-libre entonces inicio
                dejar (sucede (n));
                avanza;
            fin;
        fin;
        dejar (sucede (n));
    fin;

    define-nueva-instruccion verificar como inicio
        oeste;
        si frente-libre entonces inicio   (* si keda orientado al sur entonces avanzo *)
            avanza;
            sur;
        fin;
        si junto-a-zumbador entonces inicio
            si orientado-al-sur entonces inicio
                este;
                avanza;
            fin;
            sur;
        fin
        sino inicio
            si orientado-al-sur entonces inicio
                este;
                avanza;
            fin;
        fin;
    fin;

    define-nueva-instruccion subir (n) como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            subir (sucede (n));
            si no-orientado-al-sur entonces
                norte;
            si (frente-libre o si-es-cero (n)) y no-orientado-al-sur entonces inicio
                norte;
                avanzar (n);
                este;
                si frente-libre entonces
                    avanza;
            fin
            sino inicio
                si no-orientado-al-sur entonces
                    verificar;
                si no-orientado-al-sur entonces inicio
                    norte;
                    avanzar (n);
                    este;
                    si frente-libre entonces
                        avanza;
                fin;
                sur;
            fin;
        fin;
    fin;

    define-nueva-instruccion bajar (n) como inicio
        sur;
        si frente-libre entonces inicio
            avanzar (n);
            si frente-libre entonces inicio
                este;
                si frente-libre entonces
                    avanza;
                bajar (sucede (n));
            fin;
        fin;
    fin;

    define-nueva-instruccion contar (n) como inicio
        oeste;
        si frente-libre entonces inicio
            avanza;
            contar (sucede (n));
        fin
        sino inicio
            mientras junto-a-zumbador hacer
                coge-zumbador;
            dejar (sucede (n));
        fin;
    fin;

    inicia-ejecucion
        norte;
        subir (0);
        bajar (0);
        contar (0);
        apagate;
    termina-ejecucion
finalizar-programa
