iniciar-programa
    define-nueva-instruccion gira(z) como inicio
        repetir z veces gira-izquierda;
    fin;
    define-nueva-instruccion lanzamiento(n) como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            lanzamiento(sucede(n));
        fin;
        si frente-libre y no si-es-cero(n) entonces inicio
            repetir n veces inicio
                si no-junto-a-zumbador entonces inicio
                    repetir n veces deja-zumbador;
                    si frente-libre entonces avanza;
                fin;
            fin;
        fin;
        si no-junto-a-zumbador y no si-es-cero(n) entonces inicio
            gira(2);
            avanza;
            gira(1);
            si frente-libre entonces inicio
                avanza;
                gira(1);
            fin;
        fin;
    fin;
    define-nueva-instruccion caida(n) como inicio
        si frente-libre entonces inicio
            repetir n veces inicio
                si no-junto-a-zumbador entonces inicio
                    repetir n veces deja-zumbador;
                    si frente-libre entonces avanza;
                fin;
            fin;
            si frente-bloqueado y junto-a-zumbador entonces sal-de-instruccion;
            gira(2);
            avanza;
            gira(3);
            si frente-libre entonces inicio
                avanza;
                gira(3);
                caida(sucede(n));
            fin;
        fin;
    fin;
    define-nueva-instruccion contar(n) como inicio
        si frente-libre entonces inicio
            avanza;
            contar(sucede(n));
        fin;
        si frente-bloqueado y no-junto-a-zumbador entonces inicio
            mientras no-orientado-al-oeste hacer gira-izquierda;
            mientras frente-libre hacer avanza;
            repetir sucede(n) veces deja-zumbador;
        fin;
    fin;
    define-nueva-instruccion evaluar como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            si junto-a-zumbador entonces inicio
                coge-zumbador;
                si no-junto-a-zumbador entonces inicio
                    repetir 2 veces deja-zumbador;
                    repetir 2 veces inicio
                        si no-junto-a-zumbador entonces deja-zumbador;
                        si frente-libre entonces avanza;
                    fin;
                fin sino inicio
                    repetir 2 veces deja-zumbador;
                    si frente-libre entonces avanza;
                fin;
            fin;
        fin;
    fin;
inicia-ejecucion
    si junto-a-zumbador entonces inicio
        mientras no-orientado-al-norte hacer gira-izquierda;
        si frente-bloqueado y derecha-bloqueada entonces inicio
            mientras junto-a-zumbador hacer coge-zumbador;
            gira(2);
            mientras frente-libre hacer avanza;
            deja-zumbador;
            apagate;
        fin;
        si frente-bloqueado y derecha-libre entonces inicio
            gira(2);
            si frente-bloqueado entonces inicio
                gira(2);
                si junto-a-zumbador entonces inicio
                    mientras junto-a-zumbador hacer coge-zumbador;
                    repetir 2 veces deja-zumbador;
                    apagate;
                fin;
            fin sino gira(2);
        fin;
        si frente-libre entonces lanzamiento(0);
        mientras no-orientado-al-este hacer gira-izquierda;
        evaluar;
        mientras no-orientado-al-sur hacer gira-izquierda;
        si no-junto-a-zumbador y frente-libre entonces caida(1);
        mientras no-orientado-al-sur hacer gira-izquierda;
        mientras frente-libre hacer avanza;
        gira(3);
        mientras frente-libre hacer avanza;
        mientras junto-a-zumbador hacer coge-zumbador;
        gira(2);
        mientras no-junto-a-zumbador y frente-libre hacer avanza;
        gira(2);
        contar(0);
    fin;
        apagate;
    termina-ejecucion
finalizar-programa
  