iniciar-programa
   define-nueva-instruccion gira(n) como inicio
      repetir n veces
         gira-izquierda;
   fin;
   define-nueva-instruccion norte como inicio
      mientras no-orientado-al-norte hacer
         gira(1);
   fin;
   define-nueva-instruccion sur como inicio
      mientras no-orientado-al-sur hacer
         gira(1);
   fin;
   define-nueva-instruccion este como inicio
      mientras no-orientado-al-este hacer
         gira(1);
   fin;
   define-nueva-instruccion oeste como inicio
      mientras no-orientado-al-oeste hacer
         gira(1);
   fin;
   define-nueva-instruccion cuenta como inicio
      si frente-libre entonces inicio
         avanza;
         cuenta;
         deja-zumbador;
      fin
      sino inicio
         mientras junto-a-zumbador hacer
            coge-zumbador;
      fin;
   fin;
   define-nueva-instruccion caer(n) como inicio
      si frente-libre entonces inicio
         repetir n veces inicio
            si frente-libre entonces inicio
               repetir n veces
                  deja-zumbador;
               avanza;
            fin
            sino inicio
               repetir n veces
                  deja-zumbador;
               oeste;
               cuenta;
               deja-zumbador;
               apagate;
            fin;
         fin;
         si junto-a-zumbador entonces inicio
            apagate;
         fin
         sino inicio
            gira(2);
            avanza;
            este;
            si frente-libre entonces inicio
               avanza;
               sur;
               caer(sucede(n));
            fin
            sino inicio
               sur;
               mientras frente-libre hacer
                  avanza;
               oeste;
               cuenta;
               deja-zumbador;
               apagate;
            fin;
         fin;
      fin;

   fin;

   define-nueva-instruccion lanza(n) como inicio
      si no(si-es-cero(n)) entonces inicio
         repetir n veces inicio
            si frente-libre entonces inicio
               repetir n veces
                  deja-zumbador;
               avanza;
            fin;
         fin;
         si no-junto-a-zumbador y frente-libre entonces inicio
            gira(2);
            avanza;
            este;
            si frente-libre entonces inicio
               avanza;
               norte;
               lanza(precede(n));
            fin
            sino inicio
               sur;
               mientras frente-libre hacer
                  avanza;
               oeste;
               cuenta;
               deja-zumbador;
               apagate;
            fin;
         fin
         sino inicio
            repetir n veces
               deja-zumbador;
            este;
            si frente-libre entonces inicio
               avanza;
               lanza(0);
            fin
            sino inicio
               sur;
               mientras frente-libre hacer
                  avanza;
               oeste;
               cuenta;
               deja-zumbador;
               apagate;
            fin;
         fin;
      fin
      sino inicio
         sur;
         caer(1);
      fin;
   fin;
   define-nueva-instruccion puente(n) como inicio
      si junto-a-zumbador entonces inicio
         coge-zumbador;
         puente(sucede(n));
      fin
      sino inicio
         lanza(n);
      fin;
   fin;
   define-nueva-instruccion imp1 como inicio
      norte;
      si frente-bloqueado y izquierda-bloqueada entonces inicio
         gira(2);
         si frente-bloqueado y junto-a-zumbador y izquierda-libre entonces inicio
            repetir 5 veces
               coge-zumbador;
            apagate;
         fin;
      fin;
   fin;
   define-nueva-instruccion imp2 como inicio
      oeste;
      si frente-bloqueado y izquierda-bloqueada entonces inicio
         gira(2);
         si junto-a-zumbador y izquierda-libre y frente-libre entonces inicio
            si junto-a-zumbador entonces inicio
               coge-zumbador;
               si junto-a-zumbador entonces inicio
                  coge-zumbador;
                  si junto-a-zumbador entonces inicio
                     coge-zumbador;
                     si no-junto-a-zumbador entonces inicio
                        repetir 6 veces
                           deja-zumbador;
                        apagate;
                     fin
                     sino inicio
                        repetir 3 veces
                           deja-zumbador;
                     fin;
                  fin
                  sino inicio
                     repetir 2 veces
                        deja-zumbador;
                  fin;
               fin
               sino inicio
                  deja-zumbador;
               fin;
            fin;
         fin;
      fin;
   fin;
    inicia-ejecucion
       imp1;
       imp2;
       norte;
       puente(0);
        apagate;
    termina-ejecucion
finalizar-programa 