iniciar-programa
    define-nueva-instruccion norte como mientras no-orientado-al-norte hacer gira-izquierda;
    define-nueva-instruccion sur como mientras no-orientado-al-sur hacer gira-izquierda;
    define-nueva-instruccion este como mientras no-orientado-al-este hacer gira-izquierda;
    define-nueva-instruccion oeste como mientras no-orientado-al-oeste hacer gira-izquierda;
    define-nueva-instruccion corre como mientras frente-libre hacer avanza;

    define-nueva-instruccion cuenta_distancia(x) como inicio
        si frente-libre entonces inicio
            avanza;
            cuenta_distancia(sucede(x));
        fin sino inicio
            mientras junto-a-zumbador hacer coge-zumbador;
            repetir sucede(x) veces deja-zumbador;
            apagate;
        fin;
    fin;

    define-nueva-instruccion regreso(x) como inicio
        si frente-libre entonces inicio
            repetir x veces deja-zumbador;
            repetir precede(x) veces inicio
                si frente-libre entonces inicio
                    avanza;
                    repetir x veces deja-zumbador;
                fin sino inicio
                    oeste;
                    cuenta_distancia(0);
                fin;
            fin;
            si izquierda-libre y frente-libre entonces inicio
                este;
                avanza;
                sur;
                regreso(sucede(x));
            fin sino inicio
                sur;
                corre;
                oeste;
                cuenta_distancia(0);
            fin;
        fin sino inicio
            oeste;
            cuenta_distancia(0);
        fin;
    fin;

    define-nueva-instruccion lanzar(x) como inicio
        si no si-es-cero(x) entonces inicio
            repetir x veces deja-zumbador;
            repetir precede(x) veces inicio
                si frente-libre entonces inicio
                    avanza;
                    repetir x veces deja-zumbador;
                fin sino inicio
                    este;
                    si frente-libre entonces inicio
                        avanza;
                        sur;
                        regreso(1);
                    fin sino inicio
                        sur;
                        corre;
                        oeste;
                        cuenta_distancia(0);
                    fin;
                fin;
            fin;
            si frente-libre entonces inicio
                este;
                si frente-libre entonces avanza;
                norte;
                lanzar(precede(x));
            fin sino inicio
                si si-es-cero(precede(precede(x))) entonces inicio
                    este;
                    avanza;
                    deja-zumbador;
                    si frente-libre entonces inicio
                        avanza;
                        sur;
                        regreso(1);
                    fin sino inicio
                        sur;
                        corre;
                        oeste;
                        cuenta_distancia(0);
                    fin;
                fin;
                este;
                si frente-libre entonces inicio
                    avanza;
                    sur;
                    regreso(1);
                fin sino inicio
                    sur;
                    corre;
                    oeste;
                    cuenta_distancia(0);
                fin;
            fin;
        fin sino inicio
            sur;
            regreso(1);
        fin;
    fin;

    define-nueva-instruccion cuenta(fuerza) como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            cuenta(sucede(fuerza));
        fin sino inicio
            lanzar(fuerza);
        fin;
    fin;

    inicia-ejecucion
        norte;
        cuenta(0);
        apagate;
    termina-ejecucion
finalizar-programa
