iniciar-programa
    define-nueva-instruccion gira (n) como inicio
        repetir n veces
            gira-izquierda;
    fin;
    define-nueva-instruccion distancia (n) como inicio
        si frente-libre entonces inicio
            avanza;
            distancia (sucede(n));
        fin
        sino inicio
            mientras junto-a-zumbador hacer
                coge-zumbador;
            gira (3);
            repetir sucede (n) veces
                deja-zumbador;
            apagate;
        fin;
    fin;
    define-nueva-instruccion baja (n) como inicio
        si no si-es-cero (n) entonces inicio
            deja-zumbador;
            repetir precede (n) veces inicio
                si frente-libre entonces inicio
                    avanza;
                    deja-zumbador;
                fin
                sino inicio
                    gira (3);
                    distancia (0);
                fin;
            fin;
            si frente-bloqueado entonces inicio
                gira (3);
                distancia (0);
            fin;
            gira (1);
            si frente-libre entonces inicio
                avanza;
                gira (3);
                baja (sucede(n));
            fin
            sino inicio
                gira (3);
                mientras frente-libre hacer
                    avanza;
                gira (3);
                distancia (0);
            fin;
        fin;
    fin;
    define-nueva-instruccion sube (n) como inicio
        si no si-es-cero (n) entonces inicio
            deja-zumbador;
            repetir precede (n) veces inicio
                si frente-libre entonces inicio
                    avanza;
                    deja-zumbador;
                fin
                sino inicio
                    gira (3);
                    si frente-libre entonces inicio
                        avanza;
                        gira (3);
                        baja (1);
                    fin
                    sino inicio
                        gira (3);
                        baja (1);
                    fin;
                fin;
            fin;
            gira (3);
            si frente-libre entonces inicio
                avanza;
                gira (1);
                sube (precede(n));
            fin
            sino inicio
                gira (3);
                baja (1);
            fin;
        fin
        sino inicio
            gira (2);
            baja (1);
        fin;
    fin;
    define-nueva-instruccion piedra (n) como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            piedra (sucede(n));
        fin
        sino inicio
            mientras no-orientado-al-norte hacer
                gira (1);
            sube (n);
        fin;
    fin;
    define-nueva-instruccion piedras como inicio
        mientras no-orientado-al-sur hacer
            gira (1);
        mientras frente-libre hacer
            avanza;
        gira (2);
        repetir 19 veces inicio
            si frente-libre entonces inicio
                avanza;
            fin
            sino inicio
                gira (2);
                mientras frente-libre y no-junto-a-zumbador hacer
                    avanza;
                gira (2);
                piedra (0);
            fin;
        fin;
        gira (3);
        repetir 20 veces inicio
            si frente-libre entonces inicio
                avanza;
            fin
            sino inicio
                gira (2);
                mientras frente-libre hacer
                    avanza;
                gira (1);
                mientras frente-libre y no-junto-a-zumbador hacer
                    avanza;
                gira (2);
                piedra (0);
            fin;
        fin;
        gira (2);
        mientras frente-libre hacer
            avanza;
        gira (1);
        mientras frente-libre hacer
            avanza;
        gira (2);
        mientras junto-a-zumbador hacer
            coge-zumbador;
        repetir 11 veces
            deja-zumbador;
    fin;
    inicia-ejecucion
        piedras;
        apagate;
    termina-ejecucion
finalizar-programa