iniciar-programa
    define-nueva-instruccion gira (n) como
        repetir n veces
            gira-izquierda;

    define-nueva-instruccion norte como
        mientras no-orientado-al-norte hacer
            gira-izquierda;

    define-nueva-instruccion sur como
        mientras no-orientado-al-sur hacer
            gira-izquierda;

    define-nueva-instruccion este como
        mientras no-orientado-al-este hacer
            gira-izquierda;

    define-nueva-instruccion oeste como
        mientras no-orientado-al-oeste hacer
            gira-izquierda;

    define-nueva-instruccion avanza_a_tope como
        mientras frente-libre hacer
            avanza;

    define-nueva-instruccion deja (n) como
        repetir n veces
            si algun-zumbador-en-la-mochila entonces
                deja-zumbador;

    define-nueva-instruccion ubica1 como inicio
        oeste;
        avanza_a_tope;
        gira-izquierda;
        avanza_a_tope;
        gira-izquierda;
    fin;

    define-nueva-instruccion CogerTortas como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            si junto-a-zumbador entonces inicio
                coge-zumbador;
            fin
            sino inicio
                deja-zumbador;
            fin;
        fin;
        si no-junto-a-zumbador entonces inicio
            norte;
                si frente-libre entonces inicio
                    avanza;
                    si junto-a-zumbador entonces
                        CogerTortas;
                    sur;
                    avanza;
                fin;
            sur;
                si frente-libre entonces inicio
                    avanza;
                    si junto-a-zumbador entonces
                        CogerTortas;
                    norte;
                    avanza;
                fin;
            este;
                si frente-libre entonces inicio
                    avanza;
                    si junto-a-zumbador entonces
                        CogerTortas;
                    oeste;
                    avanza;
                fin;
            oeste;
                si frente-libre entonces inicio
                    avanza;
                    si junto-a-zumbador entonces
                        CogerTortas;
                    este;
                    avanza;
                fin;
        fin;
    fin;

    define-nueva-instruccion vuelta como inicio
        si orientado-al-norte entonces inicio
            si derecha-libre entonces inicio
                gira (3);
                avanza;
                gira (3);
            fin;
        fin
        sino inicio
            si izquierda-libre entonces inicio
                gira-izquierda;
                avanza;
                gira-izquierda;
            fin;
        fin;
    fin;

    define-nueva-instruccion repartirlas como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            si junto-a-zumbador entonces inicio
                deja-zumbador;
            fin
            sino inicio
                deja-zumbador;
                si algun-zumbador-en-la-mochila entonces inicio
                    deja (2);
                fin
                sino inicio
                    ubica1;
                fin;
            fin;
        fin;
        si no-orientado-al-este entonces inicio
            si frente-libre entonces inicio
                avanza;
                repartirlas;
            fin
            sino inicio
                vuelta;
                si frente-libre entonces inicio
                    repartirlas;
                fin
                sino inicio
                    si orientado-al-norte entonces inicio
                        si derecha-bloqueada entonces inicio
                            si junto-a-zumbador entonces inicio
                                coge-zumbador;
                                si no-junto-a-zumbador entonces inicio
                                    deja-zumbador;
                                    repartirlas;
                                fin
                                sino inicio
                                    deja-zumbador;
                                    ubica1;
                                fin;
                            fin
                            sino inicio
                                ubica1;
                            fin;
                        fin
                        sino inicio
                            repartirlas;
                        fin;
                    fin
                    sino inicio
                        si izquierda-bloqueada entonces inicio
                            si junto-a-zumbador entonces inicio
                                coge-zumbador;
                                si no-junto-a-zumbador entonces inicio
                                    deja-zumbador;
                                    repartirlas;
                                fin
                                sino inicio
                                    deja-zumbador;
                                    ubica1;
                                fin;
                            fin
                            sino inicio
                                ubica1;
                            fin;
                        fin
                        sino inicio
                            repartirlas;
                        fin;
                    fin;
                fin;
            fin;
        fin;
    fin;

    define-nueva-instruccion determinar (x) como inicio
        si algun-zumbador-en-la-mochila entonces inicio
            deja-zumbador;
            determinar (sucede (x));
        fin
        sino inicio
            si frente-bloqueado y izquierda-bloqueada y derecha-bloqueada entonces inicio
                gira (2);
                si frente-bloqueado entonces inicio
                    mientras junto-a-zumbador hacer
                        coge-zumbador;
                    deja-zumbador;
                    apagate;
                fin;
            fin;
            mientras frente-bloqueado hacer
                gira-izquierda;
            mientras junto-a-zumbador hacer
                coge-zumbador;
            avanza;
            mientras algun-zumbador-en-la-mochila hacer
                deja-zumbador;
            repetir x veces
                coge-zumbador;
            gira (2);
            avanza;
            gira (2);
            mientras algun-zumbador-en-la-mochila hacer inicio
                deja-zumbador;
                avanza;
                deja-zumbador;
                gira (2);
                avanza;
                gira (2);
            fin;
        fin;
    fin;
    
    inicia-ejecucion
        CogerTortas;
        ubica1;
        norte;
        repartirlas;
        determinar (0);
        apagate;
    termina-ejecucion
finalizar-programa