iniciar-programa
    define-nueva-instruccion gira(g) como inicio
       repetir g veces gira-izquierda;
    fin;
    define-nueva-instruccion esquina(e) como inicio
       gira(e);
       avanza;
       gira(e);
    fin;
    define-nueva-instruccion cheka como inicio
       si junto-a-zumbador entonces inicio
          coge-zumbador;
          si junto-a-zumbador entonces inicio
             deja-zumbador;
          fin sino inicio
             deja-zumbador;
             si algun-zumbador-en-la-mochila entonces inicio
                deja-zumbador;
                deja-zumbador;
             fin;
          fin;
       fin;
    fin;
    define-nueva-instruccion tortas como inicio
       si junto-a-zumbador entonces inicio
          coge-zumbador;
          si junto-a-zumbador entonces inicio
             coge-zumbador;
             repetir 4 veces inicio
                si frente-libre entonces inicio
                   avanza;
                   tortas;
                   gira(2);
                   avanza;
                   gira(2);
                fin;
                gira-izquierda;
             fin;
          fin sino inicio
             deja-zumbador;
          fin;
       fin;
    fin;
    define-nueva-instruccion alaesquina como inicio
       mientras no-orientado-al-sur hacer gira-izquierda;
       mientras frente-libre hacer avanza;
       gira(3);
       mientras frente-libre hacer avanza;
       gira(3);
    fin;
    define-nueva-instruccion repartiendo como inicio
       mientras frente-libre o ((orientado-al-norte y derecha-libre) o (orientado-al-sur y izquierda-libre)) hacer inicio
          cheka;
          si frente-libre entonces inicio
             avanza;
          fin;
          si frente-bloqueado entonces inicio
             cheka;
             si orientado-al-norte y derecha-libre entonces inicio
                esquina(3);
                cheka;
             fin sino inicio
                si orientado-al-sur y izquierda-libre entonces inicio
                   esquina(1);
                   cheka;
                fin;
             fin;
          fin;
       fin;
       alaesquina;
    fin;
    define-nueva-instruccion sobraron(s) como inicio
       si algun-zumbador-en-la-mochila entonces inicio
          deja-zumbador;
          deja-zumbador;
          sobraron(sucede(s));
       fin sino inicio
          mientras junto-a-zumbador hacer coge-zumbador;
          repetir s veces deja-zumbador;
       fin;
    fin;
    inicia-ejecucion
        tortas;
        alaesquina;
        repartiendo;
        sobraron(0);
        apagate;
    termina-ejecucion
finalizar-programa
