iniciar-programa
define-nueva-instruccion este como mientras no-orientado-al-este hacer gira-izquierda;
define-nueva-instruccion sur como mientras no-orientado-al-sur hacer gira-izquierda;
define-nueva-instruccion norte como mientras no-orientado-al-norte hacer gira-izquierda;
define-nueva-instruccion oeste como mientras no-orientado-al-oeste hacer gira-izquierda;

    define-nueva-instruccion tortas como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            si junto-a-zumbador entonces inicio
                coge-zumbador;
                norte;
                si frente-libre entonces inicio
                    avanza;
                    tortas;
                    sur;
                    avanza;
                fin;
                oeste;
                si frente-libre entonces inicio
                    avanza;
                    tortas;
                    este;
                    avanza;
                fin;
                sur;
                si frente-libre entonces inicio
                    avanza;
                    tortas;
                    norte;
                    avanza;
                fin;
                este;
                si frente-libre entonces inicio
                    avanza;
                    tortas;
                    oeste;
                    avanza;
                fin;
            fin sino deja-zumbador;
        fin;
    fin;
    define-nueva-instruccion ir11 como inicio
        oeste;
        mientras frente-libre hacer avanza;
        sur;
        mientras frente-libre hacer avanza;
        este;
    fin;
     define-nueva-instruccion deja como inicio
        coge-zumbador;
        si no-junto-a-zumbador y algun-zumbador-en-la-mochila entonces inicio
            repetir 3 veces inicio
                si algun-zumbador-en-la-mochila entonces
                deja-zumbador;
            fin;
        fin sino deja-zumbador;
    fin;
    define-nueva-instruccion checa como inicio
        mientras no-junto-a-zumbador y orientado-al-este hacer inicio
            si frente-bloqueado y orientado-al-este entonces inicio
                oeste;
                mientras frente-libre hacer avanza;
                norte;
                si frente-bloqueado entonces inicio
                    sur;
                    ir11;
                    norte;
                fin sino inicio
                    avanza;
                    este;
                fin;
            fin sino avanza;
        fin;
        si junto-a-zumbador y orientado-al-este entonces inicio
            deja;
            si frente-bloqueado y orientado-al-este entonces inicio
                oeste;
                mientras frente-libre hacer avanza;
                norte;
                si frente-libre entonces inicio
                    avanza;
                    este;
                fin sino inicio
                    ir11;
                    norte;
                fin;
            fin sino avanza;
        fin;
    fin;
    define-nueva-instruccion sobras como inicio
        si algun-zumbador-en-la-mochila entonces inicio
            repetir 2 veces deja-zumbador;
            sobras;
            deja-zumbador;
        fin sino mientras junto-a-zumbador hacer coge-zumbador;
    fin;
    inicia-ejecucion
    tortas;
    ir11;
    mientras orientado-al-este hacer inicio
        checa;
    fin;
    sobras;
        apagate;
    termina-ejecucion
finalizar-programa
