iniciar-programa
define-nueva-instruccion norte como inicio
    mientras no-orientado-al-norte hacer
        gira-izquierda;
fin;

define-nueva-instruccion sur como inicio
    mientras no-orientado-al-sur hacer
        gira-izquierda;
fin;

define-nueva-instruccion este como inicio
    mientras no-orientado-al-este hacer
        gira-izquierda;
fin;

define-nueva-instruccion oeste como inicio
    mientras no-orientado-al-oeste hacer
        gira-izquierda;
fin;

define-nueva-instruccion buscar como inicio
    si junto-a-zumbador entonces inicio
        coge-zumbador;
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            norte;
            si frente-libre entonces inicio
                avanza;
                buscar;
                sur;
                avanza;
            fin;
            sur;
            si frente-libre entonces inicio
                avanza;
                buscar;
                norte;
                avanza;
            fin;
            este;
            si frente-libre entonces inicio
                avanza;
                buscar;
                oeste;
                avanza;
            fin;
            oeste;
            si frente-libre entonces inicio
                avanza;
                buscar;
                este;
                avanza;
            fin;
        fin sino inicio
            deja-zumbador;
        fin;
    fin;
fin;

define-nueva-instruccion esquina como inicio
    sur;
    mientras frente-libre hacer inicio
        avanza;
    fin;
    oeste;
    mientras frente-libre hacer inicio
        avanza;
    fin;
fin;

define-nueva-instruccion mitad(n) como inicio
    si junto-a-zumbador entonces inicio
        repetir 2 veces inicio
            coge-zumbador;
        fin;
        mitad(sucede(n));
    fin
    sino inicio
        repetir n veces inicio
            deja-zumbador;
        fin;
    fin;
fin;

define-nueva-instruccion mochila como inicio
    mientras algun-zumbador-en-la-mochila hacer inicio
        deja-zumbador;
    fin;
    mitad(0);
fin;

define-nueva-instruccion torta(n) como inicio
    si junto-a-zumbador entonces inicio
        coge-zumbador;
        torta(sucede(n));
    fin sino inicio
        norte;
        si frente-libre entonces inicio
            avanza;
            repetir n veces inicio
                deja-zumbador;
            fin;
            sur;
            avanza;
        fin sino inicio
            este;
            si frente-libre entonces inicio
                avanza;
                repetir n veces inicio
                    deja-zumbador;
                fin;
                oeste;
                avanza;
            fin;
        fin;
        mochila;
        apagate;
    fin;
fin;

define-nueva-instruccion sobrantes como inicio
    esquina;
    si junto-a-zumbador entonces inicio
        torta(0);
    fin;
    mochila;
    apagate;
fin;

define-nueva-instruccion dejar como inicio
    si junto-a-zumbador entonces inicio
        coge-zumbador;
        si junto-a-zumbador entonces inicio
            deja-zumbador;
        fin sino inicio
            repetir 3 veces inicio
                si algun-zumbador-en-la-mochila entonces inicio
                    deja-zumbador;
                fin sino inicio
                    esquina;
                    mientras junto-a-zumbador hacer inicio
                        coge-zumbador;
                    fin;
                    apagate;
                fin;
            fin;
        fin;
    fin;
    si frente-libre entonces inicio
        avanza;
    fin sino inicio
        sur;
        mientras frente-libre hacer inicio
            avanza;
        fin;
        este;
        si frente-libre entonces inicio
            avanza;
            norte;
        fin sino inicio
            sobrantes;
        fin;
    fin;
fin;

    inicia-ejecucion
    buscar;
    esquina;
    norte;
    mientras algun-zumbador-en-la-mochila hacer inicio
        dejar;
    fin;
    si no algun-zumbador-en-la-mochila entonces inicio
        esquina;
        mientras junto-a-zumbador hacer inicio
            coge-zumbador;
        fin;
        apagate;
    fin;
        apagate;
    termina-ejecucion
finalizar-programa
