iniciar-programa
define-nueva-instruccion norte como mientras no orientado-al-norte hacer gira-izquierda;
define-nueva-instruccion sur como mientras no orientado-al-sur hacer gira-izquierda;
define-nueva-instruccion este como mientras no orientado-al-este hacer gira-izquierda;
define-nueva-instruccion oeste como mientras no orientado-al-oeste hacer gira-izquierda;

define-nueva-instruccion ir11 como
  inicio
    sur;
    mientras frente-libre hacer avanza;
    oeste;
    mientras frente-libre hacer avanza;
    este;
  fin;

define-nueva-instruccion recoger como
  inicio
    si junto-a-zumbador entonces
      inicio
        coge-zumbador;
         si junto-a-zumbador entonces
           inicio
           coge-zumbador;
             norte;
             si frente-libre entonces
               inicio
                 avanza;
                 recoger;
                 sur;
                 avanza;
               fin;
             sur;
             si frente-libre entonces
               inicio
                 avanza;
                 recoger;
                 norte;
                 avanza;
               fin;
             este;
             si frente-libre entonces
               inicio
                 avanza;
                 recoger;
                 oeste;
                 avanza;
               fin;
             oeste;
             si frente-libre entonces
               inicio
                 avanza;
                 recoger;
                 este;
                 avanza;
               fin;

           fin sino
             inicio
               deja-zumbador;
             fin;
      fin;
  fin;

 define-nueva-instruccion camina como
   inicio
     este;
     si frente-libre entonces avanza sino
       inicio
         oeste;
         mientras frente-libre hacer avanza;
         norte;
         si frente-libre entonces
           inicio
             avanza;
             este;
           fin
         sino
           inicio
              sur;
           fin;
       fin;
   fin;

 define-nueva-instruccion repartir como
   inicio
     mientras no orientado-al-sur hacer
       inicio
         si junto-a-zumbador entonces
           inicio
             coge-zumbador;
             si junto-a-zumbador entonces deja-zumbador
             sino
               inicio
                 repetir 3 veces si algun-zumbador-en-la-mochila entonces deja-zumbador;
               fin;
           fin;
         camina;
       fin;
   fin;


define-nueva-instruccion dejar como
  inicio
    si algun-zumbador-en-la-mochila entonces
      inicio
        repetir 2 veces deja-zumbador;
        dejar;
        deja-zumbador;
      fin
    sino
      inicio
        mientras junto-a-zumbador hacer coge-zumbador;
      fin;
  fin;

  inicia-ejecucion
          recoger;
          ir11;
          repartir;
          ir11;
          dejar;
        apagate;
    termina-ejecucion
finalizar-programa
