iniciar-programa

define-nueva-instruccion norte como mientras no-orientado-al-norte hacer gira-izquierda;
define-nueva-instruccion este como mientras no-orientado-al-este hacer gira-izquierda;
define-nueva-instruccion oeste como mientras no-orientado-al-oeste hacer gira-izquierda;
define-nueva-instruccion sur como mientras no-orientado-al-sur hacer gira-izquierda;

    define-nueva-instruccion busca como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            si junto-a-zumbador entonces inicio
                coge-zumbador;

                norte;
                si frente-libre entonces inicio
                    avanza;
                    busca;
                    sur;
                    avanza;
                fin;

                este;
                si frente-libre entonces inicio
                    avanza;
                    busca;
                    oeste;
                    avanza;
                fin;

                oeste;
                si frente-libre entonces inicio
                    avanza;
                    busca;
                    este;
                    avanza;
                fin;

                sur;
                si frente-libre entonces inicio
                    avanza;
                    busca;
                    norte;
                    avanza;
                fin;

            fin sino inicio
                deja-zumbador;
            fin;
        fin;
    fin;

    define-nueva-instruccion ir11 como inicio
        sur;
        mientras frente-libre hacer inicio
            avanza;
        fin;
        oeste;
        mientras frente-libre hacer inicio
            avanza;
        fin;
        este;
    fin;

    define-nueva-instruccion acomoda como inicio
        si frente-libre entonces inicio
            avanza;
        fin sino inicio
            oeste;
            mientras frente-libre hacer inicio
                avanza;
            fin;
            norte;
            si frente-libre entonces inicio
                avanza;
                este;
            fin;
        fin;
    fin;

    define-nueva-instruccion compara(x) como inicio
        si no si-es-cero(x) y no orientado-al-norte entonces inicio
            si junto-a-zumbador entonces inicio
                coge-zumbador;
                si no-junto-a-zumbador entonces inicio
                    acomoda;
                    compara(precede(x));
                fin sino inicio
                    coge-zumbador;
                    acomoda;
                    compara(x);
                fin;
            fin sino inicio
                acomoda;
                compara(x);
            fin;
        fin sino inicio
            ir11;
            si no si-es-cero(sucede(x)) entonces repetir x veces deja-zumbador;
            apagate;
        fin;
    fin;

    define-nueva-instruccion cuenta(x) como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            coge-zumbador;
            cuenta(sucede(x));
        fin sino inicio
            ir11;
            compara(x);
        fin;
    fin;

    inicia-ejecucion

        busca;
        mientras algun-zumbador-en-la-mochila hacer inicio
            deja-zumbador;
        fin;
        cuenta(0);

        apagate;
    termina-ejecucion
finalizar-programa
