iniciar-programa
    define-nueva-instruccion norte como mientras no-orientado-al-norte hacer gira-izquierda;
    define-nueva-instruccion este como mientras no-orientado-al-este hacer gira-izquierda;
    define-nueva-instruccion oeste como mientras no-orientado-al-oeste hacer gira-izquierda;
    define-nueva-instruccion sur como mientras no-orientado-al-sur hacer gira-izquierda;
    define-nueva-instruccion corre como mientras frente-libre hacer avanza;
    define-prototipo-instruccion tortas;
    define-nueva-instruccion camina como inicio
        norte;
        si frente-libre entonces inicio
            avanza;
            tortas;
            sur;
            avanza;
        fin;
        este;
        si frente-libre entonces inicio
            avanza;
            tortas;
            oeste;
            avanza;
        fin;
        sur;
        si frente-libre entonces inicio
            avanza;
            tortas;
            norte;
            avanza;
        fin;
        oeste;
        si frente-libre entonces inicio
            avanza;
            tortas;
            este;
            avanza;
        fin;
    fin;
    define-nueva-instruccion tortas como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            si junto-a-zumbador entonces inicio
                coge-zumbador;
                camina;
            fin sino inicio
                deja-zumbador;
            fin;
        fin;
    fin;
    define-nueva-instruccion cambia como inicio
        si frente-libre entonces inicio
            avanza;
        fin sino inicio
            sur;
            corre;
            este;
            si frente-libre entonces inicio
                avanza;
                norte;
            fin sino inicio
                oeste;
            fin;
        fin;
    fin;
    define-nueva-instruccion reparte como inicio
        oeste;
        corre;
        sur;
        corre;
        este;
        norte;
        mientras no-orientado-al-oeste hacer inicio
            si junto-a-zumbador entonces inicio
                coge-zumbador;
                si no-junto-a-zumbador entonces inicio
                    repetir 3 veces si algun-zumbador-en-la-mochila entonces inicio
                        deja-zumbador;
                    fin;
                fin sino inicio
                    deja-zumbador;
                fin;
            fin;
            cambia;
        fin;
    fin;
    define-nueva-instruccion respuesta como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            respuesta;
            coge-zumbador;
        fin sino inicio
            mientras algun-zumbador-en-la-mochila hacer deja-zumbador;
        fin;
    fin;
    define-nueva-instruccion entre2 como inicio
        si junto-a-zumbador entonces inicio
            repetir 2 veces coge-zumbador;
            entre2;
            deja-zumbador;
        fin;
    fin;
    inicia-ejecucion
        tortas;
        reparte;
        corre;
        respuesta;
        entre2;
        apagate;
    termina-ejecucion
finalizar-programa
