iniciar-programa

    define-nueva-instruccion gira(n) como inicio
        repetir n veces gira-izquierda;
    fin;

    define-nueva-instruccion norte como inicio
        mientras no-orientado-al-norte hacer gira-izquierda;
    fin;

    define-nueva-instruccion sur como inicio
        mientras no-orientado-al-sur hacer gira-izquierda;
    fin;

    define-nueva-instruccion este como inicio
        mientras no-orientado-al-este hacer gira-izquierda;
    fin;

    define-nueva-instruccion oeste como inicio
        mientras no-orientado-al-oeste hacer gira-izquierda;
    fin;

    define-nueva-instruccion llega11 como inicio
        sur;
        mientras frente-libre hacer avanza;
        oeste;
        mientras frente-libre hacer avanza;
        este;
    fin;

    define-nueva-instruccion buscar como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            si no-junto-a-zumbador entonces inicio
                deja-zumbador;
            fin sino inicio
                coge-zumbador;

                norte;
                si frente-libre entonces inicio
                    avanza;
                    buscar;
                    sur;
                    avanza;
                fin;

                sur;
                si frente-libre entonces inicio
                    avanza;
                    buscar;
                    norte;
                    avanza;
                fin;

                este;
                si frente-libre entonces inicio
                    avanza;
                    buscar;
                    oeste;
                    avanza;
                fin;

                oeste;
                si frente-libre entonces inicio
                    avanza;
                    buscar;
                    este;
                    avanza;
                fin;
            fin;
        fin;
    fin;

    define-nueva-instruccion paso como inicio
        si frente-libre entonces inicio
            avanza;
        fin sino inicio
            norte;
            si frente-libre entonces inicio
                si derecha-bloqueada entonces inicio
                    avanza;
                    gira(1);
                fin sino inicio
                    avanza;
                    gira(3);
                fin;
            fin;
        fin;
    fin;

    define-nueva-instruccion reparte como inicio
        mientras no-orientado-al-norte hacer inicio
            si junto-a-zumbador entonces inicio
                coge-zumbador;
                si junto-a-zumbador entonces inicio
                    deja-zumbador;
                fin sino inicio
                    repetir 3 veces si algun-zumbador-en-la-mochila entonces deja-zumbador;
                fin;
            fin;
            paso;
        fin;
    fin;

    define-nueva-instruccion junto como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            junto;
            deja-zumbador;
        fin sino inicio
            este;
            paso;
        fin;
    fin;

    define-nueva-instruccion deja como inicio
        si algun-zumbador-en-la-mochila entonces inicio
            repetir 2 veces deja-zumbador;
            deja;
            coge-zumbador;
        fin;
    fin;

    inicia-ejecucion
        buscar;
        llega11;
        reparte;
        llega11;
        junto;
        llega11;
        deja;
        apagate;
    termina-ejecucion
finalizar-programa
