iniciar-programa
define-prototipo-instruccion busqueda;
define-nueva-instruccion gira(q) como repetir q veces gira-izquierda;

define-nueva-instruccion reparte(x) como inicio
    si si-es-cero(x) entonces inicio
    fin sino inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            si junto-a-zumbador entonces inicio
                deja-zumbador;
            fin sino inicio
                reparte(precede(x));
            fin;
        fin;
        si frente-libre entonces inicio
            avanza;
            reparte(x);
        fin sino inicio
            gira(1);
            si frente-libre entonces inicio
                avanza;
                gira(1);
                mientras frente-libre hacer avanza;
                gira(2);
                reparte(x);
            fin;
        fin;
    fin;
        mientras no orientado-al-sur hacer gira-izquierda;
        mientras frente-libre hacer avanza;
        gira(3);
        mientras frente-libre hacer avanza;
        mientras junto-a-zumbador hacer coge-zumbador;
        repetir x veces deja-zumbador;
        apagate;
fin;

define-nueva-instruccion cuenta(x) como inicio
    si junto-a-zumbador entonces inicio
        coge-zumbador;
        cuenta(sucede(x));
    fin sino inicio
        mientras no orientado-al-sur hacer gira-izquierda;
        mientras frente-libre hacer avanza;
        gira(3);
        mientras frente-libre hacer avanza;
        gira(2);
        reparte(x);
    fin;
fin;

define-nueva-instruccion comprovar como inicio
    avanza;
    si junto-a-zumbador entonces inicio
        busqueda;
        si junto-a-zumbador entonces inicio
            mientras junto-a-zumbador hacer inicio
                coge-zumbador;
                gira(2);
                avanza;
                gira(2);
                deja-zumbador;
                avanza;
            fin;
            gira(2);
            avanza;
            gira(2);
        fin;
    fin sino inicio
        gira(2);
        avanza;
        gira(2);
    fin;
fin;

define-nueva-instruccion contar como inicio
    si junto-a-zumbador entonces inicio
        coge-zumbador;
        contar;
        deja-zumbador;
    fin sino inicio
        comprovar;
    fin;
fin;

define-nueva-instruccion busqueda como inicio
    si junto-a-zumbador entonces inicio
        coge-zumbador;
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            si no junto-a-zumbador entonces inicio
                busqueda;
                deja-zumbador;
            fin sino inicio
                repetir 2 veces deja-zumbador;
                gira(2);
                avanza;
                gira(2);
            fin;
        fin sino inicio
            deja-zumbador;
            gira(2);
            avanza;
            gira(2);
        fin;
    fin sino inicio
        repetir 4 veces inicio
            si junto-a-zumbador entonces inicio
                coge-zumbador;
                si junto-a-zumbador entonces inicio
                    coge-zumbador;
                    si frente-libre entonces contar;
                    repetir 2 veces deja-zumbador;
                fin sino inicio
                    si frente-libre entonces comprovar;
                    deja-zumbador;
                fin;
            fin sino inicio
                si frente-libre entonces comprovar;
            fin;
            gira(1);
        fin;
    fin;
fin;


    inicia-ejecucion
    busqueda;
    cuenta(0);
        apagate;
    termina-ejecucion
finalizar-programa
