iniciar-programa
    define-nueva-instruccion gira(z) como inicio
        repetir z veces gira-izquierda;
    fin;
    define-nueva-instruccion p11 como inicio
        mientras no-orientado-al-sur hacer gira-izquierda;
        mientras frente-libre hacer avanza;
        gira(3);
        mientras frente-libre hacer avanza;
        gira(3);
    fin;
    define-nueva-instruccion tortas como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            si junto-a-zumbador entonces inicio
                coge-zumbador;
                repetir 4 veces inicio
                    si frente-libre entonces inicio
                        avanza;
                        tortas;
                        gira(2);
                        avanza;
                        gira(2);
                    fin;
                    gira(1);
                fin;
            fin sino deja-zumbador;
        fin;
    fin;
    define-nueva-instruccion alumnos(n) como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            si no-junto-a-zumbador entonces inicio
                alumnos(sucede(n));
                sal-de-instruccion;
            fin sino inicio
                mientras junto-a-zumbador hacer coge-zumbador;
            fin;
        fin;
        si no-junto-a-zumbador y no-orientado-al-este entonces inicio
            mientras no-junto-a-zumbador y frente-libre hacer avanza;
            si junto-a-zumbador entonces inicio
                alumnos(n);
                sal-de-instruccion;
            fin;
            si frente-bloqueado y no-junto-a-zumbador entonces inicio
                gira(2);
                mientras frente-libre hacer avanza;
                gira(1);
                si frente-libre entonces inicio
                    avanza;
                    gira(1);
                    alumnos(n);
                    sal-de-instruccion;
                fin sino inicio
                    p11;
                    si no si-es-cero(n) entonces repetir n veces deja-zumbador;
                fin;
            fin;
        fin;
    fin;
    define-nueva-instruccion quitar(n) como inicio
        si no si-es-cero(n) y junto-a-zumbador entonces inicio
            coge-zumbador;
            quitar(precede(n));
            sal-de-instruccion;
        fin;
        si no-junto-a-zumbador y no si-es-cero(n) entonces inicio
            repetir n veces deja-zumbador;
        fin;
        si junto-a-zumbador y si-es-cero(n) entonces inicio
            mientras junto-a-zumbador hacer coge-zumbador;
        fin;
    fin;
    define-nueva-instruccion contar-tortas(n) como inicio
        si junto-a-zumbador entonces inicio
            repetir 2 veces coge-zumbador;
            contar-tortas(sucede(n));
            sal-de-instruccion;
        fin;
        si no-junto-a-zumbador entonces inicio
            p11;
            alumnos(0);
            quitar(n);
        fin;
    fin;
inicia-ejecucion
    tortas;
    mientras algun-zumbador-en-la-mochila hacer deja-zumbador;
    contar-tortas(0);
        apagate;
    termina-ejecucion
finalizar-programa
