iniciar-programa

define-nueva-instruccion gira(n) como repetir n veces gira-izquierda;

define-nueva-instruccion bp como inicio
    si junto-a-zumbador entonces inicio
        coge-zumbador;
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            repetir 4 veces inicio
                si frente-libre entonces inicio
                    avanza;
                    bp;
                    gira(2);
                    avanza;
                    gira(2);
                fin;
                gira(1);
            fin;
        fin sino inicio
            deja-zumbador;
        fin;
    fin;
fin;

define-nueva-instruccion repartir_aux como inicio
    coge-zumbador;
    si no-junto-a-zumbador entonces inicio
        deja-zumbador;
        si algun-zumbador-en-la-mochila entonces repetir 2 veces deja-zumbador;
    fin sino inicio
        deja-zumbador;
    fin;
fin;

define-nueva-instruccion repartir como inicio
    mientras izquierda-libre o frente-libre  hacer inicio
        si junto-a-zumbador entonces repartir_aux;
        mientras frente-libre hacer inicio
            avanza;
            si junto-a-zumbador entonces repartir_aux;
        fin;
        si izquierda-libre entonces inicio
            gira(2);
            mientras frente-libre hacer avanza;
            gira(3);
            avanza;
            gira(3);
        fin;
    fin;
fin;

define-nueva-instruccion final(x) como inicio
    si algun-zumbador-en-la-mochila entonces inicio
        repetir 2 veces deja-zumbador;
        final(sucede(x));
    fin sino inicio
        mientras junto-a-zumbador hacer coge-zumbador;
        repetir x veces deja-zumbador;
    fin;
fin;

    inicia-ejecucion

    bp;
    mientras no-orientado-al-este hacer gira(1);
    repetir 2 veces inicio
        mientras frente-libre hacer avanza;
        gira(1);
    fin;
    repartir;
    si junto-a-zumbador entonces repartir_aux;
    si algun-zumbador-en-la-mochila entonces inicio
        final(0);
    fin sino inicio
        mientras junto-a-zumbador hacer coge-zumbador;
        apagate;
    fin;

        apagate;
    termina-ejecucion
finalizar-programa
