iniciar-programa
define-nueva-instruccion g(n) como
    repetir n veces gira-izquierda;
define-nueva-instruccion trae como
inicio
     g(2);
     avanza;
     mientras junto-a-zumbador hacer
     inicio
         repetir 2 veces
         coge-zumbador;
         g(2);
         si frente-libre entonces avanza;
         g(2);
         repetir 2 veces
         deja-zumbador;
         avanza;
     fin;
     g(2);
     avanza;
fin;
define-nueva-instruccion lleva como
inicio
    avanza;
    mientras junto-a-zumbador hacer
    inicio
        repetir 2 veces
        coge-zumbador;
        g(2);
        si frente-libre entonces avanza;
        g(2);
        repetir 2 veces
        deja-zumbador;
        si frente-libre entonces avanza;
    fin;
    g(2);
    si frente-libre entonces avanza;
    g(2);
fin;
define-nueva-instruccion dfsc como
inicio
    si no-junto-a-zumbador entonces deja-zumbador;
    repetir 4 veces
    inicio
        si frente-libre entonces
        inicio
            avanza;
            si junto-a-zumbador entonces
            inicio
                trae;
                dfsc;
            fin;
            g(2);
            avanza;
            g(2);
            lleva;
        fin;
        g(1);
    fin;
fin;
define-nueva-instruccion elimina como
inicio
    si orientado-al-norte o orientado-al-sur entonces
    inicio
        si junto-a-zumbador entonces
        inicio
            coge-zumbador;
            si junto-a-zumbador entonces
            coge-zumbador
            sino
            deja-zumbador;
        fin;
        si frente-libre entonces
        avanza
        sino
        inicio
            mientras no-orientado-al-este hacer
            gira-izquierda;
            si frente-libre entonces
            inicio
                avanza;
                si derecha-bloqueada entonces
                gira-izquierda
                sino
                g(3);
            fin
            sino
            inicio
            fin;
        fin;
    fin;
fin;
define-nueva-instruccion pasa(n) como
inicio
    si junto-a-zumbador entonces
    inicio
        coge-zumbador;
        pasa(sucede(n))
    fin
    sino
    inicio
        avanza;
        repetir n veces
        deja-zumbador;
        g(2);
        avanza;
        g(2);
    fin;
fin;
define-nueva-instruccion resta(n) como
inicio
    si junto-a-zumbador entonces
    inicio
        coge-zumbador;
        resta(sucede(n))
    fin
    sino
    inicio
        avanza;
        repetir n veces
        si junto-a-zumbador entonces
        coge-zumbador;
    fin;
fin;
define-nueva-instruccion acaba(n) como
inicio
    si junto-a-zumbador entonces
    inicio
        repetir 2 veces
        coge-zumbador;
        acaba(sucede(n))
    fin
    sino
    inicio
        mientras no-orientado-al-oeste hacer
        gira-izquierda;
        mientras frente-libre hacer
        avanza;
        gira-izquierda;
        mientras frente-libre hacer
        avanza;
        g(2);
        si frente-bloqueado y derecha-bloqueada entonces
        inicio
            repetir n veces deja-zumbador;
            apagate;
        fin;
        si junto-a-zumbador entonces
        pasa(0);
        g(3);
        repetir 2 veces
        repetir n veces
        deja-zumbador;
        si frente-libre entonces
        avanza
        sino
        inicio
            gira-izquierda;
            avanza;
            pasa(0);
            mientras algun-zumbador-en-la-mochila hacer
            deja-zumbador;
            g(2);
            resta(0);
            repetir n veces
            si junto-a-zumbador entonces
            coge-zumbador;
            apagate;
        fin;
        si junto-a-zumbador entonces
        inicio
            si frente-bloqueado entonces
            gira-izquierda;
            pasa(0);
            mientras no-orientado-al-oeste hacer
            gira-izquierda;
        fin
        sino
        inicio
            g(2);
        fin;
        mientras algun-zumbador-en-la-mochila hacer
        deja-zumbador;
        resta(0);
        repetir n veces
        si junto-a-zumbador entonces
        coge-zumbador;
        apagate;
    fin;
fin;
define-nueva-instruccion checa(n) como
inicio
    si frente-libre entonces
    inicio
        avanza;
        si junto-a-zumbador entonces
        inicio
            coge-zumbador;
            si junto-a-zumbador entonces
            deja-zumbador;
        fin;
        checa(sucede(n))
    fin
    sino
    inicio
        g(2);
        repetir n veces
        avanza;
    fin;
fin;
define-nueva-instruccion recheca(n) como
inicio
    si frente-libre entonces
    inicio
        avanza;
        si junto-a-zumbador entonces
        inicio
            coge-zumbador;
            si junto-a-zumbador entonces
            deja-zumbador;
        fin;
        gira-izquierda;
        checa(0);
        checa(0);
        g(3);
        recheca(sucede(n))
    fin
    sino
    inicio
        g(2);
        repetir n veces
        avanza;
    fin;
fin;
inicia-ejecucion
    mientras no-orientado-al-norte hacer
    gira-izquierda;
    checa(0);
    checa(0);
    gira-izquierda;
    recheca(0);
    recheca(0);
    dfsc;
    acaba(0);
        apagate;
    termina-ejecucion
finalizar-programa
