iniciar-programa
    define-nueva-instruccion norte como mientras no orientado-al-norte hacer gira-izquierdA;
    define-nueva-instruccion oeste como mientras no orientado-al-oeste hacer gira-izquierdA;
    define-nueva-instruccion este como mientras no orientado-al-este hacer gira-izquierdA;
    define-nueva-instruccion sur como mientras no orientado-al-sur hacer gira-izquierdA;

    define-nueva-instruccion ir11 como inicio
        sur;
        mientras frente-libre hacer inicio
            avanza;
        fin;
        oeste;
        mientras frente-libre hacer inicio
            avanza;
        fin;
        este;
    fin;

    define-nueva-instruccion juntar como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            si no junto-a-zumbador entonces inicio
                deja-zumbador;
            fin sino inicio
                coge-zumbador;
                norte;
                si frente-libre entonces inicio
                    avanza;
                    juntar;
                    sur;
                    avanza;
                fin;
                este;
                si frente-libre entonces inicio
                    avanza;
                    juntar;
                    oeste;
                    avanza;
                fin;
                sur;
                si frente-libre entonces inicio
                    avanza;
                    juntar;                       
                    norte;
                    avanza;
                fin;
                oeste;
                si frente-libre entonces inicio
                    avanza;
                    juntar;
                    este;
                    avanza;
                fin;
            fin;
        fin;
    fin;

    define-nueva-instruccion dejar como inicio
        si algun-zumbador-en-la-mochila entonces inicio
            si junto-a-zumbador entonces inicio
                coge-zumbador;
                si no junto-a-zumbador entonces inicio
                    repetir 3 veces deja-zumbador;
                fin sino deja-zumbador;
            fin;
        fin;
    fin;

    define-nueva-instruccion avanzar como inicio
        si frente-libre entonces inicio
            avanza;
        fin sino inicio
            norte;
            avanza;
            oeste;
            mientras frente-libre hacer inicio
                avanzA;
            fin;
            este;
        fin;
    fin;

    define-nueva-instruccion repartir como inicio
        ir11;
        mientras frente-libre o izquierda-libre hacer inicio
            dejar;
            avanzar;
        fin;
        dejar;
        ir11;
    fin;

    define-nueva-instruccion tortas como inicio
        si algun-zumbador-en-la-mochila entonces inicio
            deja-zumbador;
            deja-zumbador;
            tortas;
            deja-zumbador;
        fin sino inicio
            mientras junto-a-zumbador hacer inicio
                coge-zumbador;
            fin;
        fin;
    fin;

    inicia-ejecucion
        juntar;
        repartir;
        tortas;
        apagate;
    termina-ejecucion
finalizar-programa
