iniciar-programa
    define-nueva-instruccion norte como mientras no-orientado-al-norte hacer gira-izquierda;
    define-nueva-instruccion sur como mientras no-orientado-al-sur hacer gira-izquierda;
    define-nueva-instruccion este como mientras no-orientado-al-este hacer gira-izquierda;
    define-nueva-instruccion oeste como mientras no-orientado-al-oeste hacer gira-izquierda;
    define-nueva-instruccion corre como mientras frente-libre hacer avanza;

    define-nueva-instruccion busca como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            si junto-a-zumbador entonces inicio
                coge-zumbador;
                busca;
            fin sino inicio
                deja-zumbador;
            fin;
        fin sino inicio
            norte;
            si frente-libre entonces inicio
                avanza;
                si junto-a-zumbador entonces busca;
                sur;
                avanza;
            fin;

            sur;
            si frente-libre entonces inicio
                avanza;
                si junto-a-zumbador entonces busca;
                norte;
                avanza;
            fin;

            este;
            si frente-libre entonces inicio
                avanza;
                si junto-a-zumbador entonces busca;
                oeste;
                avanza;
            fin;

            oeste;
            si frente-libre entonces inicio
                avanza;
                si junto-a-zumbador entonces busca;
                este;
                avanza;
            fin;
        fin;
    fin;

    define-nueva-instruccion ini como inicio
        sur;
        corre;
        oeste;
        corre;
        norte;
    fin;

    define-nueva-instruccion dejar(x) como inicio
        si si-es-cero(x) entonces inicio
            ini;
            apagate;
        fin;
        mientras no-junto-a-zumbador y frente-libre hacer avanza;
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            si junto-a-zumbador entonces inicio
                mientras junto-a-zumbador hacer coge-zumbador;
                dejar(x);
            fin sino inicio
                dejar(precede(x));
            fin;
        fin sino inicio
            si derecha-libre entonces inicio
                este;
                avanza;
                sur;
                corre;
                norte;
                dejar(x);
            fin sino inicio
                ini;
                mientras junto-a-zumbador hacer coge-zumbador;
                repetir x veces deja-zumbador;
                apagate;
            fin;
        fin;
    fin;

    define-nueva-instruccion unos(tortas) como inicio
        si algun-zumbador-en-la-mochila entonces inicio
            repetir 2 veces deja-zumbador;
            unos(sucede(tortas));
        fin sino inicio
            repetir tortas veces repetir 2 veces coge-zumbador;
            dejar(tortas);
        fin;
    fin;

    inicia-ejecucion
        busca;
        ini;
        unos(0);

        apagate;
    termina-ejecucion
finalizar-programa
