iniciar-programa

    define-nueva-instruccion norte como
    inicio
        mientras no-orientado-al-norte hacer
        inicio
            gira-izquierda;
        fin;
    fin;

    define-nueva-instruccion sur como
    inicio
        mientras no-orientado-al-sur hacer
        inicio
            gira-izquierda;
        fin;
    fin;

    define-nueva-instruccion este como
    inicio
        mientras no-orientado-al-este hacer
        inicio
            gira-izquierda;
        fin;
    fin;

    define-nueva-instruccion oeste como
    inicio
        mientras no-orientado-al-oeste hacer
        inicio
            gira-izquierda;
        fin;
    fin;

    define-nueva-instruccion gira-derecha como
    inicio
        repetir 3 veces
        inicio
            gira-izquierda;
        fin;
    fin;

    define-nueva-instruccion gira-doble como
    inicio
        repetir 2 veces
        inicio
            gira-izquierda;
        fin;
    fin;

    define-nueva-instruccion camina como
    inicio
        mientras frente-libre hacer
        inicio
            avanza;
        fin;
    fin;

    define-nueva-instruccion volver-a-k como
    inicio
        sur;
        camina;
        oeste;
        camina;
        este;
    fin;

    define-nueva-instruccion busqueda como
    inicio
        si junto-a-zumbador entonces
        inicio
            coge-zumbador;
            si junto-a-zumbador entonces
            inicio
               coge-zumbador;
               norte;
               si frente-libre entonces
               inicio
                   avanza;
                   busqueda;
                   sur;
                   avanza;
               fin;
               sur;
               si frente-libre entonces
               inicio
                   avanza;
                   busqueda;
                   norte;
                   avanza;
               fin;
               este;
               si frente-libre entonces
               inicio
                   avanza;
                   busqueda;
                   oeste;
                   avanza;
               fin;
               oeste;
               si frente-libre entonces
               inicio
                   avanza;
                   busqueda;
                   este;
                   avanza;
               fin;
            fin
            sino
            inicio
                deja-zumbador;
            fin;
        fin;
    fin;

    define-nueva-instruccion ir como
    inicio
        este;
        si (junto-a-zumbador y algun-zumbador-en-la-mochila) entonces
        inicio
            coge-zumbador;
            si junto-a-zumbador entonces
            inicio
                deja-zumbador;
            fin
            sino
            inicio
                repetir 3 veces
                inicio
                    deja-zumbador;
                fin;
            fin;
        fin;
        mientras frente-libre hacer
        inicio
            avanza;
            si (junto-a-zumbador y algun-zumbador-en-la-mochila) entonces
            inicio
                coge-zumbador;
                si junto-a-zumbador entonces
                inicio
                    deja-zumbador;
                fin
                sino
                inicio
                    repetir 3 veces
                    inicio
                        deja-zumbador;
                    fin;
                fin;
            fin;
        fin;
    fin;

    define-nueva-instruccion regresar como
    inicio
        oeste;
        camina;
    fin;

    define-nueva-instruccion pasar como
    inicio
        norte;
        si frente-libre entonces
        inicio
           avanza;
        fin
        sino
        inicio
            este;
            camina;
        fin;
    fin;

    define-nueva-instruccion repartir como
    inicio
        ir;
        regresar;
        pasar;
        este;
    fin;

    define-nueva-instruccion posar(n) como
    inicio
        si junto-a-zumbador entonces
        inicio
            coge-zumbador;
            coge-zumbador;
            posar(sucede(n));
        fin
        sino
        inicio
            repetir n veces
            inicio
                deja-zumbador;
            fin;
        fin;
    fin;

    define-nueva-instruccion parche(x) como
    inicio
        si junto-a-zumbador entonces
        inicio
            coge-zumbador;
            parche(sucede(x));
        fin
        sino
        inicio
            norte;
            si frente-libre entonces
            inicio
               avanza;
               repetir x veces
               inicio
                   deja-zumbador;
               fin;
               volver-a-k;
            fin
            sino
            inicio
                este;
                si frente-libre entonces
                inicio
                   avanza;
                   repetir x veces
                   inicio
                       deja-zumbador;
                   fin;
                fin
                sino
                inicio
                    mientras algun-zumbador-en-la-mochila hacer
                    inicio
                        deja-zumbador;
                    fin;
                    coge-zumbador;
                    si junto-a-zumbador entonces
                    inicio
                       apagate;
                    fin
                    sino
                    inicio
                        apagate;
                    fin;
                fin;
            fin;
        fin;
    fin;

    inicia-ejecucion
        busqueda;
        volver-a-k;
        mientras (no(frente-bloqueado y izquierda-bloqueada)) hacer
        inicio
            repartir;
        fin;
        si algun-zumbador-en-la-mochila entonces
        inicio
            volver-a-k;
            si junto-a-zumbador entonces
            inicio
                parche(0);
            fin;
            volver-a-k;
            mientras algun-zumbador-en-la-mochila hacer
            inicio
                deja-zumbador;
            fin;
            posar(0);
        fin
        sino
        inicio
            volver-a-k;
            parche(0);
        fin;
        apagate;
    termina-ejecucion
finalizar-programa
