iniciar-programa
    define-nueva-instruccion gira (n) como inicio
        repetir n veces
            gira-izquierda;
    fin;
    define-nueva-instruccion norte como inicio
        mientras no-orientado-al-norte hacer
            gira (1);
    fin;
    define-nueva-instruccion este como inicio
        mientras no-orientado-al-este hacer
            gira (1);
    fin;
    define-nueva-instruccion sur como inicio
        mientras no-orientado-al-sur hacer
            gira (1);
    fin;
    define-nueva-instruccion oeste como inicio
        mientras no-orientado-al-oeste hacer
            gira (1);
    fin;
    define-nueva-instruccion busca como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            si junto-a-zumbador entonces inicio
                coge-zumbador;
                repetir 4 veces inicio
                    si frente-libre entonces inicio
                        avanza;
                        busca;
                        gira (2);
                        avanza;
                        gira (2);
                    fin;
                    gira (1);
                fin;
            fin
            sino inicio
                deja-zumbador;
            fin;
        fin;
    fin;
    define-nueva-instruccion orienta como inicio
        sur;
        mientras frente-libre hacer
            avanza;
        oeste;
        mientras frente-libre hacer
            avanza;
        norte;
    fin;
    define-nueva-instruccion reparte como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            si no-junto-a-zumbador entonces inicio
                deja-zumbador;
                si algun-zumbador-en-la-mochila entonces inicio
                    repetir 2 veces
                        deja-zumbador;
                fin
                sino inicio
                    orienta;
                    mientras junto-a-zumbador hacer
                        coge-zumbador;
                    apagate;
                fin;
                si frente-libre entonces inicio
                    avanza;
                    reparte;
                fin
                sino inicio
                    si derecha-libre entonces inicio
                        sur;
                        mientras frente-libre hacer
                            avanza;
                        este;
                        avanza;
                        norte;
                        reparte;
                    fin
                    sino inicio
                        orienta;
                    fin;
                fin;
            fin
            sino inicio
                deja-zumbador;
                si frente-libre entonces inicio
                    avanza;
                    reparte;
                fin
                sino inicio
                    si derecha-libre entonces inicio
                        sur;
                        mientras frente-libre hacer
                            avanza;
                        este;
                        avanza;
                        norte;
                        reparte;
                    fin
                    sino inicio
                        orienta;
                    fin;
                fin;
            fin;
        fin
        sino inicio
            si frente-libre entonces inicio
                avanza;
                reparte;
            fin
            sino inicio
                si derecha-libre entonces inicio
                    sur;
                    mientras frente-libre hacer
                        avanza;
                    este;
                    avanza;
                    norte;
                    reparte;
                fin
                sino inicio
                    orienta;
                fin;
            fin;
        fin;
    fin;
    define-nueva-instruccion chistoso (n) como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            chistoso (sucede(n));
        fin
        sino inicio
            mientras algun-zumbador-en-la-mochila hacer
                deja-zumbador;
            repetir n veces
                coge-zumbador;
        fin;
    fin;
    define-nueva-instruccion entre como inicio
        si junto-a-zumbador entonces inicio
            repetir 2 veces
                coge-zumbador;
            entre;
            deja-zumbador;
        fin;
    fin;
    define-nueva-instruccion divide como inicio
        si junto-a-zumbador entonces inicio
            chistoso (0);
        fin
        sino inicio
            mientras algun-zumbador-en-la-mochila hacer
                deja-zumbador;
        fin;
        entre;
    fin;
    define-nueva-instruccion tortas como inicio
        busca;
        orienta;
        reparte;
        divide;
    fin;
    inicia-ejecucion
        tortas;
        apagate;
    termina-ejecucion
finalizar-programa