iniciar-programa

define-nueva-instruccion norte como mientras no-orientado-al-norte hacer gira-izquierda;
define-nueva-instruccion sur como mientras no-orientado-al-sur hacer gira-izquierda;
define-nueva-instruccion este como mientras no-orientado-al-este hacer gira-izquierda;
define-nueva-instruccion oeste como mientras no-orientado-al-oeste hacer gira-izquierda;
define-nueva-instruccion choca como mientras frente-libre hacer avanza;

define-nueva-instruccion pos11-norte como inicio
    sur;
    choca;
    oeste;
    choca;
    norte;
fin;

define-nueva-instruccion pon-1 como inicio
    sur;
    choca;
    oeste;
    choca;
    norte;
    mientras junto-a-zumbador y frente-libre hacer avanza;
    deja-zumbador;
fin;

define-nueva-instruccion pon-2 como inicio
    sur;
    choca;
    oeste;
    choca;
    este;
    avanza;
    norte;
    mientras junto-a-zumbador y frente-libre hacer avanza;
    deja-zumbador;
    deja-zumbador;
fin;

define-nueva-instruccion pon-3 como inicio
    pon-1;
    pon-2;
fin;

define-nueva-instruccion recursa como inicio
    si junto-a-zumbador entonces inicio
        coge-zumbador;
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            si junto-a-zumbador entonces inicio
                coge-zumbador;
                recursa;
                pon-3;
            fin sino inicio
                recursa;
                pon-2;
            fin;
        fin sino inicio
            recursa;
            pon-1;
         fin;
    fin sino inicio
        si frente-libre entonces inicio
            avanza;
            recursa;
        fin sino inicio
            repetir 3 veces gira-izquierda;
            si frente-libre entonces inicio
                avanza;
                sur;
                choca;
                norte;
                recursa;
            fin sino inicio
                pos11-norte;
            fin;
        fin;
   fin;
fin;

    inicia-ejecucion
        pos11-norte;
        recursa;
        apagate;
    termina-ejecucion
finalizar-programa
