iniciar-programa
    define-nueva-instruccion oeste como inicio
        mientras no-orientado-al-oeste hacer gira-izquierda;
    fin;

    define-nueva-instruccion este como inicio
        mientras no-orientado-al-este hacer gira-izquierda;
    fin;

    define-nueva-instruccion sur como inicio
        mientras no-orientado-al-sur hacer gira-izquierda;
    fin;

    define-nueva-instruccion norte como inicio
        mientras no-orientado-al-norte hacer gira-izquierda;
    fin;

    define-nueva-instruccion orientar como inicio
        oeste;
        mientras frente-libre hacer avanza;
        sur;
        mientras frente-libre hacer avanza;
        norte;
    fin;

    define-nueva-instruccion  recorrer como inicio
        mientras frente-libre y no junto-a-zumbador hacer avanza;
    fin;

    define-nueva-instruccion otraColumna como inicio
        si orientado-al-norte entonces inicio
            este;
            si frente-libre entonces inicio
                avanza;
                sur;
            fin;
        fin
        sino inicio
            este;
            si frente-libre entonces inicio
                avanza;
                norte;
            fin;
        fin;
    fin;

    define-nueva-instruccion regresar como inicio
        oeste;
        mientras frente-libre hacer avanza;
        sur;
        mientras frente-libre hacer avanza;
        norte;
    fin;

    define-nueva-instruccion acomodar como inicio
        mientras frente-libre y no-junto-a-zumbador  hacer avanza;
        si frente-bloqueado y no-junto-a-zumbador entonces inicio
            otraColumna;
            mientras no-junto-a-zumbador y no-orientado-al-este hacer inicio
                recorrer;
                si frente-bloqueado y no-junto-a-zumbador entonces otraColumna;
            fin;
        fin;
    fin;

    define-nueva-instruccion filas como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            si no-junto-a-zumbador entonces inicio
                acomodar;
                filas;
                sur;
                mientras frente-libre hacer avanza;
                oeste;
                mientras frente-libre hacer avanza;
                norte;
                mientras junto-a-zumbador hacer avanza;
                deja-zumbador;
            fin
            sino inicio
                si junto-a-zumbador entonces inicio
                    coge-zumbador;
                    acomodar;
                    filas;
                    oeste;
                    mientras frente-libre hacer avanza;
                    sur;
                    mientras frente-libre hacer avanza;
                    este;
                    avanza;
                    norte;
                    mientras junto-a-zumbador hacer avanza;
                    repetir 2 veces deja-zumbador;
                fin;
            fin;
        fin
        sino inicio
            regresar;
        fin;
    fin;

    inicia-ejecucion
        orientar;
        mientras no-junto-a-zumbador y no-orientado-al-este hacer inicio
            recorrer;
            si frente-bloqueado y no-junto-a-zumbador entonces otraColumna;
        fin;
        filas;
        apagate;
    termina-ejecucion
finalizar-programa
