iniciar-programa
define-nueva-instruccion gira-derecha como
inicio
    gira-izquierda;
    gira-izquierda;
    gira-izquierda;
fin;
define-nueva-instruccion revisar como
inicio
    gira-derecha;
    mientras junto-a-zumbador hacer coge-zumbador;
    avanza;
    mientras junto-a-zumbador y frente-libre hacer avanza;
    mientras algun-zumbador-en-la-mochila hacer deja-zumbador;
    gira-izquierda; gira-izquierda;
    mientras frente-libre hacer avanza;
    gira-derecha;
    si frente-libre entonces
    inicio
        avanza;
        revisar;
    fin
    sino inicio
        mientras junto-a-zumbador hacer coge-zumbador;
        gira-derecha;
        avanza;
        mientras no-junto-a-zumbador y frente-libre hacer avanza;
        mientras algun-zumbador-en-la-mochila hacer deja-zumbador;
        gira-izquierda; gira-izquierda;
        mientras frente-libre hacer avanza;
        gira-izquierda;
        mientras frente-libre hacer avanza;
        gira-izquierda; gira-izquierda;
    fin;
fin;
define-nueva-instruccion revisar-dos como
inicio
    gira-izquierda;
    mientras junto-a-zumbador hacer coge-zumbador;
    avanza;
    mientras junto-a-zumbador y frente-libre hacer avanza;
    mientras algun-zumbador-en-la-mochila hacer deja-zumbador;
    gira-izquierda; gira-izquierda;
    mientras frente-libre hacer avanza;
    gira-izquierda;
    si frente-libre entonces
    inicio
        avanza;
        revisar-dos;
    fin
    sino inicio
        mientras junto-a-zumbador hacer coge-zumbador;
        gira-izquierda;
        avanza;
        mientras no-junto-a-zumbador y frente-libre hacer avanza;
        mientras algun-zumbador-en-la-mochila hacer deja-zumbador;
        gira-izquierda; gira-izquierda;
        mientras frente-libre hacer avanza;
        gira-derecha;
        mientras frente-libre hacer avanza;
        gira-izquierda; gira-izquierda;
    fin;
fin;
define-nueva-instruccion ordenar-hombres como
inicio
    mientras no-orientado-al-este hacer gira-izquierda;
    mientras orientado-al-este y frente-libre hacer
    inicio
        avanza;
        si junto-a-zumbador entonces
        inicio
            coge-zumbador;
            si junto-a-zumbador entonces
            inicio
                deja-zumbador;

                ordenar-hombres;
            fin
            sino inicio
                gira-izquierda; gira-izquierda;
                mientras frente-libre hacer avanza;
                gira-derecha;
                deja-zumbador;
                ordenar-hombres;
            fin;
        fin;
    fin;
    si frente-bloqueado y orientado-al-este entonces
    inicio
        gira-izquierda; gira-izquierda;
        mientras frente-libre hacer avanza;
        gira-derecha;
        si frente-libre entonces
        inicio
            avanza;
            ordenar-hombres;
        fin
        sino inicio
            mientras no-orientado-al-oeste hacer gira-izquierda;
            mientras frente-libre hacer avanza;
            gira-izquierda;
            mientras frente-libre hacer avanza;
        fin;
    fin;
fin;
define-nueva-instruccion revisar-tres como
inicio
    mientras no-orientado-al-este hacer gira-izquierda;
    avanza;
    mientras junto-a-zumbador hacer coge-zumbador;
    avanza;
    mientras junto-a-zumbador y frente-libre hacer avanza;
    mientras algun-zumbador-en-la-mochila hacer deja-zumbador;
    gira-izquierda; gira-izquierda;
    mientras frente-libre hacer avanza;
    gira-derecha;
    si frente-libre entonces
    inicio
        avanza;
        revisar-tres;
    fin
    sino inicio
        mientras no-orientado-al-este hacer gira-izquierda;
        avanza;
        mientras junto-a-zumbador hacer coge-zumbador;
        avanza;
        mientras no-junto-a-zumbador y frente-libre hacer avanza;
        mientras algun-zumbador-en-la-mochila hacer deja-zumbador;
        gira-izquierda; gira-izquierda;
        mientras frente-libre hacer avanza;
        gira-izquierda;
        mientras frente-libre hacer avanza;
        gira-izquierda; gira-izquierda;
    fin;
fin;
define-nueva-instruccion ordenar-mujeres como
inicio
    mientras no-orientado-al-este hacer gira-izquierda;
    si frente-libre entonces avanza;
    mientras orientado-al-este y frente-libre hacer
    inicio
        avanza;
        si junto-a-zumbador entonces
        inicio
            coge-zumbador;
            si junto-a-zumbador entonces
            inicio
                coge-zumbador;
                si junto-a-zumbador entonces
                inicio
                    deja-zumbador;
                    deja-zumbador;
                    si frente-libre entonces avanza;
                    ordenar-mujeres;
                fin
                sino inicio
                    gira-izquierda; gira-izquierda;
                    mientras frente-libre hacer avanza;
                    gira-izquierda; gira-izquierda;
                    avanza;
                    deja-zumbador;
                    deja-zumbador;
                    gira-izquierda; gira-izquierda;
                    avanza;
                    gira-izquierda; gira-izquierda;
                    ordenar-mujeres;
                fin;
            fin;
        fin;
    fin;
    si frente-bloqueado y orientado-al-este entonces
    inicio
        gira-izquierda; gira-izquierda;
        mientras frente-libre hacer avanza;
        gira-derecha;
        si frente-libre entonces
        inicio
            avanza;
            ordenar-mujeres;
        fin
        sino inicio
            mientras no-orientado-al-oeste hacer gira-izquierda;
            mientras frente-libre hacer avanza;
            gira-izquierda;
            mientras frente-libre hacer avanza;
        fin;
    fin;
fin;
define-nueva-instruccion ordenar-parejas como
inicio
    mientras no-orientado-al-este hacer gira-izquierda;
    si frente-libre entonces avanza;
    si frente-libre entonces avanza;
    mientras orientado-al-este y frente-libre hacer
    inicio
        si no-junto-a-zumbador entonces avanza;
        si junto-a-zumbador entonces
        inicio
            mientras junto-a-zumbador hacer coge-zumbador;
            gira-izquierda; gira-izquierda;
            mientras frente-libre hacer avanza;
            gira-izquierda; gira-izquierda;
            deja-zumbador;
            avanza;
            deja-zumbador;
            deja-zumbador;
            gira-izquierda; gira-izquierda;
            avanza;
            gira-izquierda; gira-izquierda;
            ordenar-parejas;
        fin
        sino inicio
            si frente-libre entonces avanza;
        fin;
    fin;
    si frente-bloqueado y orientado-al-este entonces
    inicio
        gira-izquierda; gira-izquierda;
        mientras frente-libre hacer avanza;
        gira-derecha;
        si frente-libre entonces
        inicio
            avanza;
            ordenar-parejas;
        fin
        sino inicio
            mientras no-orientado-al-oeste hacer gira-izquierda;
            mientras frente-libre hacer avanza;
            gira-izquierda;
            mientras frente-libre hacer avanza;
        fin;
    fin;
fin;
define-nueva-instruccion amontonar como
inicio
    mientras junto-a-zumbador hacer coge-zumbador;
    mientras orientado-al-norte y no-junto-a-zumbador y frente-libre hacer
    inicio
        si frente-libre entonces avanza;
        mientras junto-a-zumbador hacer coge-zumbador;
    fin;
    gira-izquierda; gira-izquierda;
    mientras frente-libre hacer avanza;
    gira-izquierda; gira-izquierda;
    mientras algun-zumbador-en-la-mochila hacer
    inicio
        deja-zumbador;
        si frente-libre entonces avanza;
    fin;
    gira-izquierda; gira-izquierda;
    mientras frente-libre hacer avanza;
fin;
define-nueva-instruccion amontonar-dos como
inicio
    mientras junto-a-zumbador hacer coge-zumbador;
    mientras orientado-al-norte y no-junto-a-zumbador y frente-libre hacer
    inicio
        si frente-libre entonces avanza;
        mientras junto-a-zumbador hacer coge-zumbador;
    fin;
    gira-izquierda; gira-izquierda;
    mientras frente-libre hacer avanza;
    gira-izquierda; gira-izquierda;
    mientras algun-zumbador-en-la-mochila hacer
    inicio
        deja-zumbador;
        deja-zumbador;
        si frente-libre entonces avanza;
    fin;
    gira-izquierda; gira-izquierda;
    mientras frente-libre hacer avanza;
fin;
    inicia-ejecucion
        mientras no-orientado-al-oeste hacer gira-izquierda;
        mientras frente-libre hacer avanza;
        gira-izquierda;
        mientras frente-libre hacer avanza;
        gira-izquierda; gira-izquierda;
        revisar;
        gira-derecha;
        mientras frente-libre hacer avanza;
        gira-izquierda;
        revisar-dos;
        mientras no-orientado-al-oeste hacer gira-izquierda;
        mientras frente-libre hacer avanza;
        gira-derecha;
        ordenar-hombres;
        gira-izquierda; gira-izquierda;
        revisar-tres;
        ordenar-mujeres;
        gira-izquierda; gira-izquierda;
        ordenar-parejas;
        gira-izquierda; gira-izquierda;
        amontonar;
        mientras no-orientado-al-este hacer gira-izquierda;
        avanza;
        gira-izquierda;
        amontonar-dos;
        apagate;
    termina-ejecucion
finalizar-programa 