iniciar-programa

    define-nueva-instruccion norte como mientras no orientado-al-norte hacer gira-izquierda;
    define-nueva-instruccion sur como mientras no orientado-al-sur hacer gira-izquierda;
    define-nueva-instruccion este como mientras no orientado-al-este hacer gira-izquierda;
    define-nueva-instruccion oeste como mientras no orientado-al-oeste hacer gira-izquierda;

    define-nueva-instruccion quita(n) como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            quita(n);
            coge-zumbador;
        fin sino inicio
            repetir n veces deja-zumbador;
        fin;
    fin;

    define-nueva-instruccion compara(n) como inicio
        norte;
        repetir n veces inicio
            si junto-a-zumbador y no orientado-al-sur entonces inicio
                norte;
                coge-zumbador;
            fin sino inicio
                sur;
                deja-zumbador;
            fin;
        fin;
        si orientado-al-norte entonces inicio
            mientras junto-a-zumbador hacer coge-zumbador;
            repetir n veces deja-zumbador;
        fin sino inicio
            quita(n);
        fin;
    fin;


    define-nueva-instruccion busqueda(n) como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            si junto-a-zumbador entonces inicio
                coge-zumbador;
                si junto-a-zumbador entonces inicio
                    repetir 2 veces deja-zumbador;
                    compara(sucede(sucede(n)));
                fin sino inicio
                    repetir sucede(sucede(n)) veces deja-zumbador;
                fin;
            fin sino inicio
                deja-zumbador;
            fin;
        fin sino inicio
            deja-zumbador;
            si orientado-al-este entonces inicio
                norte;
                si frente-libre entonces inicio
                    avanza;
                    busqueda(sucede(n));
                    sur;
                    avanza;
                    este;
                fin;
                sur;
                si frente-libre entonces inicio
                    avanza;
                    busqueda(sucede(n));
                    norte;
                    avanza;
                    este;
                fin;
                este;
                si frente-libre entonces inicio
                    avanza;
                    busqueda(n);
                    oeste;
                    avanza;
                    este;
                fin;
                oeste;
                si frente-libre entonces inicio
                    avanza;
                    busqueda(sucede(n));
                    este;
                    avanza;
                    este;
                fin;
            fin sino inicio
                si orientado-al-oeste entonces inicio
                    norte;
                    si frente-libre entonces inicio
                        avanza;
                        busqueda(sucede(n));
                        sur;
                        avanza;
                        oeste;
                    fin;
                    sur;
                    si frente-libre entonces inicio
                        avanza;
                        busqueda(sucede(n));
                        norte;
                        avanza;
                        oeste;
                    fin;
                    este;
                    si frente-libre entonces inicio
                        avanza;
                        busqueda(sucede(n));
                        oeste;
                        avanza;
                        oeste;
                    fin;
                    oeste;
                    si frente-libre entonces inicio
                        avanza;
                        busqueda(n);
                        este;
                        avanza;
                        oeste;
                    fin;
                fin sino inicio
                    si orientado-al-norte entonces inicio
                        norte;
                        si frente-libre entonces inicio
                            avanza;
                            si si-es-cero(n) entonces inicio
                                busqueda(sucede(n));
                            fin sino inicio
                                busqueda(n);
                            fin;
                            sur;
                            avanza;
                            norte;
                        fin;
                        sur;
                        si frente-libre entonces inicio
                            avanza;
                            busqueda(sucede(n));
                            norte;
                            avanza;
                            norte;
                        fin;
                        este;
                        si frente-libre entonces inicio
                            avanza;
                            busqueda(sucede(n));
                            oeste;
                            avanza;
                            norte;
                        fin;
                        oeste;
                        si frente-libre entonces inicio
                            avanza;
                            busqueda(sucede(n));
                            este;
                            avanza;
                            norte;
                        fin;
                    fin sino inicio
                        si orientado-al-sur entonces inicio
                            norte;
                            si frente-libre entonces inicio
                                avanza;
                                busqueda(sucede(n));
                                sur;
                                avanza;
                                sur;
                            fin;
                            sur;
                            si frente-libre entonces inicio
                                avanza;
                                busqueda(n);
                                norte;
                                avanza;
                                sur;
                            fin;
                            este;
                            si frente-libre entonces inicio
                                avanza;
                                busqueda(sucede(n));
                                oeste;
                                avanza;
                                sur;
                            fin;
                            oeste;
                            si frente-libre entonces inicio
                                avanza;
                                busqueda(sucede(n));
                                este;
                                avanza;
                                sur;
                            fin;
                        fin;
                    fin;
                fin;
            fin;
            coge-zumbador;
        fin;
    fin;

    define-nueva-instruccion final como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            si junto-a-zumbador entonces inicio
                coge-zumbador;
                coge-zumbador;
                apagate;
            fin sino inicio
                deja-zumbador;
            fin;
        fin sino inicio
            deja-zumbador;
            norte;
            si frente-libre entonces inicio
                avanza;
                final;
                sur;
                avanza;
            fin;
            sur;
            si frente-libre entonces inicio
                avanza;
                final;
                norte;
                avanza;
            fin;
            este;
            si frente-libre entonces inicio
                avanza;
                final;
                oeste;
                avanza;
            fin;
            oeste;
            si frente-libre entonces inicio
                avanza;
                final;
                este;
                avanza;
            fin;
        fin;
    fin;

    inicia-ejecucion
        norte;
        busqueda(0);
        final;
        apagate;
    termina-ejecucion
finalizar-programa
